Zum Hauptinhalt springen

Benutzerdefinierte Sensorkonfiguration

Was dieses Beispiel zeigt​

Das Beispiel customConfig baut einen eigenen sensorType namens SENSOR_CUSTOM, statt eines der Presets der Bibliothek zu verwenden, übergibt ihn dem Konstruktor und gibt die Gaskonzentration alle 2,5 Sekunden in ppm aus. Der lange Kommentar im Sketch listet jedes Feld und die Werte auf, die es annehmen kann.

Die eigenen Werte des Beispiels entsprechen nicht denen der SGX-4CO-Kohlenmonoxidzelle dieses Boards. Das Preset der Bibliothek für diese Zelle ist SENSOR_CO, und zwei Felder unterscheiden sich:

FeldIm BeispielWert in SENSOR_CO
nanoAmperesPerPPM100.0F70.0F
internalZeroCalibration00
adsGainADS_GAIN_4_096VADS_GAIN_4_096V
TIA_GAIN_IN_KOHMSTIA_GAIN_120_KOHMTIA_GAIN_14_KOHM
RLOADRLOAD_10_OHMRLOAD_10_OHM
REF_SOURCEREF_EXTERNALREF_EXTERNAL
INTERNAL_ZEROINTERNAL_ZERO_20_PERCENTINTERNAL_ZERO_20_PERCENT
BIAS_SIGNBIAS_SIGN_NEGATIVEBIAS_SIGN_NEGATIVE
BIASBIAS_0_PERCENTBIAS_0_PERCENT
FET_SHORTFET_SHORT_DISABLEDFET_SHORT_DISABLED
OP_MODEOP_MODE_3LEAD_AMP_CELLOP_MODE_3LEAD_AMP_CELL

Setzen Sie vor dem Hochladen in SENSOR_CUSTOM nanoAmperesPerPPM auf 70.0F und TIA_GAIN_IN_KOHMS auf TIA_GAIN_14_KOHM, damit die Konfiguration zur Zelle dieses Boards passt. Die übrigen Felder haben bereits die Werte von SENSOR_CO.

Was es auf diesem Board braucht​

Das Beispiel erzeugt den Sensor mit der Standardadresse des Konstruktors, 0x49. Bei einer Adresse außerhalb von 0x30 bis 0x37 läuft die Bibliothek nicht über die Bridge des Boards: begin() startet den ADS1115 an dieser Adresse und schreibt die Konfiguration des LMP91000 selbst, über das I2C des Controllers. Auf diesem Board liegen diese beiden Chips am internen Bus, den die obere Stiftleiste als SDA2 und SCL2 herausführt. Die Qwiic-Connectors und SDA1/SCL1 erreichen nur die ATtiny404-Bridge, und ein I2C-Scan über Qwiic findet nur die Bridge, im Auslieferungszustand unter 0x30. Das Beispiel übergibt keinen Config-Pin, und LMPEN ist auf dem Board auf GND gelegt; siehe Hardware-Details.

Verdrahten Sie für dieses Beispiel daher die obere Stiftleiste, nicht das Qwiic-Kabel: Verbinden Sie SDA Ihres Controllers mit SDA2, SCL mit SCL2, den 3,3-V-Pin mit 3V3 und GND mit GND. Über Qwiic antwortet nur die Bridge.

Die Adresse der Bridge, 0x30 bis 0x37, ist die, die das Beispiel CO-Konzentration auslesen übergibt.

Der Beispielcode​

Select Board
customConfig.ino
/**
**************************************************
*
* @file customConfig.ino
* @brief Create a custom config for the LMP91000 and upload it to the device.
* This enables you to use this breakout with any electrochemical sensor.
*
* To successfully run the sketch:
* - Edit the custom configuration
* - Connect LMPEN to any GPIO pin
* - Run the sketch and open serial monitor at 115200 baud!
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

/**
* Here are parameters to configure for the custom sensor:
*
* nanoAmperesPerPPM: From the datasheet of the particular electrochemical
* sensor, used in the calculation of PPM/PPB
*
* internalZeroCalibration: A fixed value which is summed to the voltage
* measured by the ADS. The value here should make the reading be
* just barely 0 PPM when the sensor is in a place with none of the target gas
*
* adsGain: The gain of the ADS
* The voltage here represents the max range which it can measure
* ADS_GAIN_6_144V 6.144 V
* ADS_GAIN_4_096V 4.096 V
* ADS_GAIN_2_048V 2.048 V
* ADS_GAIN_1_024V 1.024 V
* ADS_GAIN_0_512V 0.512 V
* ADS_GAIN_0_256V 0.256 V
*
* TIA_GAIN_IN_KOHMS: The gain of the amplifier
* This increases the sensitivity of the measurement
* TIA_GAIN_EXTERNAL External resistance
* TIA_GAIN_2_75_KOHM 2.75 kOhm
* TIA_GAIN_3_5_KOHM 3.5 kOhm
* TIA_GAIN_7_KOHM 7 kOhm
* TIA_GAIN_14_KOHM 14 kOhm
* TIA_GAIN_35_KOHM 35 kOhm
* TIA_GAIN_120_KOHM 120 kOhm
* TIA_GAIN_350_KOHM 350 kOhm
*
* RLOAD: The load resistor in the LMP91000
* Specified in the electrochemical sensor's datasheet
* RLOAD_10_OHM 10 Ohm
* RLOAD_33_OHM 33 Ohm
* RLOAD_50_OHM 50 Ohm
* RLOAD_100_OHM 100 Ohm
*
* REF_SOURCE: Source of the control voltage reference
* For our breakout, use external, there's a 2.5V external
* reference voltage
* REF_INTERNAL Internal
* REF_EXTERNAL External
*
* INTERNAL_ZERO: Internal zero selection
* If the electrochemical sensor has a positive polarity, you
* would usually want to use 20% for the most headroom in the signal
* INTERNAL_ZERO_20_PERCENT 20%
* INTERNAL_ZERO_50_PERCENT 50%
* INTERNAL_ZERO_67_PERCENT 67%
* INTERNAL_ZERO_BYPASSED Internal zero bypassed
*
* BIAS_SIGN: The polarity of the bias voltage
* BIAS_SIGN_NEGATIVE Negative
* BIAS_SIGN_POSITIVE Positive
*
* BIAS: Added bias, percentage of the reference voltage
* Most sensors don't require this, check each sensor's datasheet
* BIAS_0_PERCENT 0%
* BIAS_1_PERCENT 1%
* BIAS_2_PERCENT 2%
* BIAS_4_PERCENT 4%
* BIAS_6_PERCENT 6%
* ...
* BIAS_22_PERCENT 22%
* BIAS_24_PERCENT 24%
*
* FET_SHORT: Short the FET
* Used to perserve the electrochemical sensor
* Has to be disabled for the sensor to be operable
* FET_SHORT_DISABLED Disabled
* FET_SHORT_ENABLED Enabled
*
* OP_MODE: Mode of operation
* OP_MODE_DEEP_SLEEP Deep Sleep (default)
* OP_MODE_2LEAD_GROUND_CELL 2-lead ground referred galvanic cell
* OP_MODE_STANDBY Standby
* OP_MODE_3LEAD_AMP_CELL 3-lead amperometric cell
* OP_MODE_TEMPERATURE_TIA_OFF Temperature measurement (TIA Off)
* OP_MODE_TEMPERATURE_TIA_ON Temperature measurement (TIA On)
*
* For more details, check thge LMP91000 datasheet, chapter 7.6
*/

// Here is an example of a custom configuration:
const sensorType SENSOR_CUSTOM = {
100.0F, // nanoAmperesPerPPM
0, // internalZeroCalibration
ADS_GAIN_4_096V, // adsGain
TIA_GAIN_120_KOHM, // TIA_GAIN_IN_KOHMS
RLOAD_10_OHM, // RLOAD
REF_EXTERNAL, // REF_SOURCE
INTERNAL_ZERO_20_PERCENT, // INTERNAL_ZERO
BIAS_SIGN_NEGATIVE, // BIAS_SIGN
BIAS_0_PERCENT, // BIAS
FET_SHORT_DISABLED, // FET_SHORT
OP_MODE_3LEAD_AMP_CELL, // OP_MODE
};

// Create the sensor object with the custom type
ElectrochemicalGasSensor sensor(SENSOR_CUSTOM);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// Print the reading with 5 digits of precision
Serial.println("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Die folgenden Zeilen stammen aus einem Lauf dieses Beispiels auf diesem Board, wobei der Controller wie oben beschrieben mit den Pins SDA2, SCL2, 3V3 und GND der Stiftleiste verbunden war.

Erwartetes Ergebnis im Serial Monitor bei 115200 Baud:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!
Sensor reading:
0.31747 PPM
Sensor reading:
0.31796 PPM
Sensor reading:
0.30993 PPM
Sensor reading:
0.29262 PPM

Danach gibt der Sketch alle 2,5 Sekunden Sensor reading: in einer eigenen Zeile aus, gefolgt von einer Zeile mit der Konzentration in ppm mit fünf Nachkommastellen und PPM. Ein Ergebnis unter null wird als 0.00000 ausgegeben. Schlägt begin() fehl, gibt der Sketch ERROR: Can't init the sensor! Check connections! aus und hält an.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erzeugt das Sensorobjekt. Das Beispiel übergibt SENSOR_CUSTOM und belässt die Adresse und den Config-Pin bei ihren Standardwerten. Ein sensorType enthält der Reihe nach: nanoAmperesPerPPM, internalZeroCalibration, adsGain, TIA_GAIN_IN_KOHMS, RLOAD, REF_SOURCE, INTERNAL_ZERO, BIAS_SIGN, BIAS, FET_SHORT und OP_MODE.

ReturnsKonstruktor.

Parameter

ParameterTypBeschreibung
_tsensorTypeDie Konfiguration der Zelle: ein Preset der Bibliothek oder Ihr eigener sensorType. Für die SGX-4CO-Zelle dieses Boards ist das Preset der Bibliothek SENSOR_CO.
_adcAddruint8_tDie I2C-Adresse. Standard DEFAULT_ADC_ADDR, 0x49. Von 0x30 bis 0x37 kommuniziert die Bibliothek mit der ATtiny404-Bridge des Boards.
_configPinintEin GPIO, den die Bibliothek während des Sendens der Front-End-Konfiguration auf Low und sonst auf High setzt. Wird bei einer Adresse von 0x30 bis 0x37 nicht verwendet. Standard -1, keiner.
bool begin()returns bool

Startet I2C mit Wire.begin(). Bei einer Adresse von 0x30 bis 0x37 prüft es, ob die Bridge antwortet, und sendet ihr die ADC-Verstärkung und die Datenrate aus der Konfiguration sowie die Front-End-Einstellungen, wobei es auf jede Antwort bis zu 500 ms wartet. Bei jeder anderen Adresse startet es den ADC an dieser Adresse, stellt dessen Verstärkung und seine langsamste Datenrate ein und schreibt dann die Front-End-Einstellungen.

Returnstrue, wenn jeder Schritt erfolgreich war, sonst false.

double getPPM()returns double

Führt eine ADC-Wandlung der Ausgangsspannung des Front-Ends durch, zieht den internen Nullpunkt der Konfiguration ab, addiert deren Nullpunktkalibrierung und rechnet den Zellenstrom mit der Empfindlichkeit und der Verstärkung des Verstärkers in ppm um.

ReturnsDie Gaskonzentration in ppm. Ein negatives Ergebnis wird als 0 zurückgegeben.

Zusammenfassung​

Füllen Sie einen sensorType mit den Werten Ihrer Zelle aus (für dieses Board die oben genannten Werte von SENSOR_CO), übergeben Sie ihn dem Konstruktor, rufen Sie begin() einmal in setup() auf und prüfen Sie das Ergebnis, lesen Sie dann mit getPPM().