Zum Hauptinhalt springen

Die CO-Konzentration auslesen

Was dieses Beispiel zeigt​

Das Beispiel bridgeBoard startet das Board mit seiner Standardadresse 0x30 und dem Preset SENSOR_CO für die SGX-4CO-Zelle. Danach gibt es alle 2,5 Sekunden die Kohlenmonoxidkonzentration in ppm aus.

Bei diesem Board kommuniziert die Bibliothek mit der ATtiny404-Bridge, nicht direkt mit dem Frontend und dem ADC: Jede Adresse von 0x30 bis 0x37 wählt diesen Modus. Die Bridge richtet den LMP91000 und den ADS1115 am internen Bus des Boards ein, daher schließen Sie LMPEN an nichts an.

Der Beispielcode​

Select Board
bridgeBoard.ino
/**
**************************************************
*
* @file bridgeBoard.ino
* @brief See how to init a sensor on the new ATtiny404 bridge board revision,
*
* To successfully run the sketch:
* - Set the desired address using the jumpers on the back of the board
* (address = 0x30 + jumper offset, giving a range of 0x30-0x37)
* - Run the sketch and open serial monitor at 115200 baud!
*
* Note: on this board revision, LMPEN is hardwired to GND, so there's
* no configPin argument to pass - the constructor's third argument
* is ignored whenever the address falls in the bridge range (0x30-0x37).
*
* @authors @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Any additional boards on the same bus just need a different jumper setting
// (0x30-0x37), same as twoSensors.ino does for legacy boards with 0x49/0x4A/0x4B.
ElectrochemicalGasSensor sensor(SENSOR_CO, 0x30);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections and jumper address!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Bei diesem Board wird die Adresse mit dem DIP-Schalter ADDRESS mit drei Schaltern auf der Oberseite oben links eingestellt, nicht mit Jumpern auf der Rückseite, und die Standardadresse 0x30 muss nicht geändert werden. LMPEN ist über 10 kΩ auf GND gelegt, statt direkt damit verbunden zu sein; in beiden Fällen schließen Sie nichts daran an.

Erwartetes Ergebnis im Serial Monitor bei 115200 Baud, sobald das Board antwortet:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!
Sensor reading: 0.29711 PPM
Sensor reading: 0.29430 PPM
Sensor reading: 0.32846 PPM
Sensor reading: 0.29958 PPM

Danach folgt alle 2,5 Sekunden eine Zeile: Sensor reading: , die Konzentration in ppm mit fünf Nachkommastellen und PPM. Ein Ergebnis unter null wird als 0.00000 ausgegeben. Antwortet das Board nicht, gibt der Sketch ERROR: Can't init the sensor! Check connections and jumper address! aus und stoppt.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erstellt das Sensorobjekt. Das Beispiel übergibt SENSOR_CO und 0x30, die Adresse des Boards im Auslieferungszustand; bei einer Adresse von 0x30 bis 0x37 kommuniziert die Bibliothek mit der ATtiny404-Bridge des Boards.

ReturnsKonstruktor.

Parameter

ParameterTypBeschreibung
_tsensorTypeDas Preset der Zelle. Für die SGX-4CO-Zelle dieses Boards verwenden Sie SENSOR_CO (70 nA/ppm, ADC-Bereich 4,096 V, Verstärkung des Verstärkers 14 kΩ, 20 % interner Nullpunkt).
_adcAddruint8_tDie I2C-Adresse. Standard ist DEFAULT_ADC_ADDR, 0x49. Von 0x30 bis 0x37 kommuniziert die Bibliothek mit der ATtiny404-Bridge des Boards.
_configPinintEin GPIO, den die Bibliothek auf Low zieht, während sie die Konfiguration des Frontends sendet, und sonst auf High. Wird bei einer Adresse von 0x30 bis 0x37 nicht verwendet. Standard ist -1, also keiner.
bool begin()returns bool

Startet I2C mit Wire.begin(), prüft dann bei einer Bridge-Adresse, ob die Bridge antwortet, sendet ihr die ADC-Verstärkung und die Datenrate aus dem Preset und sendet die Konfiguration des Frontends. Jeder Schritt wartet bis zu 500 ms auf die Antwort der Bridge.

Returnstrue, wenn jeder Schritt erfolgreich war, false, wenn das Board nicht geantwortet oder einen Fehler gemeldet hat.

double getPPM()returns double

Lässt die Bridge eine ADC-Wandlung der Ausgangsspannung des Frontends durchführen, zieht den internen Nullpunkt ab (20 % der 2,5-V-Referenz bei SENSOR_CO), addiert die Nullpunktkalibrierung und rechnet den Zellenstrom mit der Empfindlichkeit des Presets in ppm um.

ReturnsDie Gaskonzentration in ppm. Ein negatives Ergebnis wird als 0 zurückgegeben.

double getPPB()returns double

Dieselbe Messung wie getPPM(), in Parts per Billion. Das Beispiel zeigt sie als auskommentierte Alternative.

ReturnsgetPPM() multipliziert mit 1000.

Zusammenfügen​

Erstellen Sie das Objekt mit SENSOR_CO und der Adresse des Boards, rufen Sie begin() einmal in setup() auf und prüfen Sie das Ergebnis. Rufen Sie dann getPPM() auf, wann immer Sie einen Messwert möchten. Für ein zweites Board am selben Bus geben Sie ihm mit seinen Adressschaltern eine andere Adresse und erstellen ein zweites Objekt mit dieser Adresse.