Zum Hauptinhalt springen

Eigene Zelle konfigurieren

Was dieses Beispiel zeigt​

Das Beispiel customConfig baut seinen eigenen sensorType auf, statt eine Voreinstellung zu verwenden. So können Sie jeden Wert aus dem Datenblatt Ihrer Zelle einstellen. Es sendet die Werte an den LMP91000 und gibt die Gaskonzentration alle 2,5 Sekunden in Parts per Million (PPM) aus.

Verbinden Sie Ihren Controller für dieses Beispiel mit dem oberen Header und nicht mit einem Qwiic-Connector: SDA des Controllers mit SDA2, SCL mit SCL2, die 3,3-V-Versorgung mit 3V3 und Masse mit GND. Bei dieser Adresse kommuniziert die Bibliothek direkt über SDA2 und SCL2 mit dem ADS1115 und dem LMP91000; die ATtiny404-Bridge des Boards bei 0x30 wird nicht verwendet. Über Qwiic funktioniert nur das Bridge-Beispiel in der Schnellstart-Anleitung.

Der Beispielcode​

Passen Sie die Werte in SENSOR_CUSTOM an Ihre Zelle an; der lange Kommentar darüber listet die Auswahlmöglichkeiten für jedes Feld auf. Der Sketch erstellt den Sensor nur mit SENSOR_CUSTOM, daher wird die Standardadresse der Bibliothek verwendet.

Der Kommentar im Sketch besagt, dass LMPEN mit einem GPIO verbunden werden soll. Auf diesem Board führt LMPEN zum Header und zum ATtiny404 des Boards.

Select Board
customConfig.ino
/**
**************************************************
*
* @file customConfig.ino
* @brief Create a custom config for the LMP91000 and upload it to the device.
* This enables you to use this breakout with any electrochemical sensor.
*
* To successfully run the sketch:
* - Edit the custom configuration
* - Connect LMPEN to any GPIO pin
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

/**
* Here are parameters to configure for the custom sensor:
*
* nanoAmperesPerPPM: From the datasheet of the particular electrochemical
* sensor, used in the calculation of PPM/PPB
*
* internalZeroCalibration: A fixed value which is summed to the voltage
* measured by the ADS. The value here should make the reading be
* just barely 0 PPM when the sensor is in a place with none of the target gas
*
* adsGain: The gain of the ADS
* The voltage here represents the max range which it can measure
* ADS_GAIN_6_144V 6.144 V
* ADS_GAIN_4_096V 4.096 V
* ADS_GAIN_2_048V 2.048 V
* ADS_GAIN_1_024V 1.024 V
* ADS_GAIN_0_512V 0.512 V
* ADS_GAIN_0_256V 0.256 V
*
* TIA_GAIN_IN_KOHMS: The gain of the amplifier
* This increases the sensitivity of the measurement
* TIA_GAIN_EXTERNAL External resistance
* TIA_GAIN_2_75_KOHM 2.75 kOhm
* TIA_GAIN_3_5_KOHM 3.5 kOhm
* TIA_GAIN_7_KOHM 7 kOhm
* TIA_GAIN_14_KOHM 14 kOhm
* TIA_GAIN_35_KOHM 35 kOhm
* TIA_GAIN_120_KOHM 120 kOhm
* TIA_GAIN_350_KOHM 350 kOhm
*
* RLOAD: The load resistor in the LMP91000
* Specified in the electrochemical sensor's datasheet
* RLOAD_10_OHM 10 Ohm
* RLOAD_33_OHM 33 Ohm
* RLOAD_50_OHM 50 Ohm
* RLOAD_100_OHM 100 Ohm
*
* REF_SOURCE: Source of the control voltage reference
* For our breakout, use external, there's a 2.5V external
* reference voltage
* REF_INTERNAL Internal
* REF_EXTERNAL External
*
* INTERNAL_ZERO: Internal zero selection
* If the electrochemical sensor has a positive polarity, you
* would usually want to use 20% for the most headroom in the signal
* INTERNAL_ZERO_20_PERCENT 20%
* INTERNAL_ZERO_50_PERCENT 50%
* INTERNAL_ZERO_67_PERCENT 67%
* INTERNAL_ZERO_BYPASSED Internal zero bypassed
*
* BIAS_SIGN: The polarity of the bias voltage
* BIAS_SIGN_NEGATIVE Negative
* BIAS_SIGN_POSITIVE Positive
*
* BIAS: Added bias, percentage of the reference voltage
* Most sensors don't require this, check each sensor's datasheet
* BIAS_0_PERCENT 0%
* BIAS_1_PERCENT 1%
* BIAS_2_PERCENT 2%
* BIAS_4_PERCENT 4%
* BIAS_6_PERCENT 6%
* ...
* BIAS_22_PERCENT 22%
* BIAS_24_PERCENT 24%
*
* FET_SHORT: Short the FET
* Used to perserve the electrochemical sensor
* Has to be disabled for the sensor to be operable
* FET_SHORT_DISABLED Disabled
* FET_SHORT_ENABLED Enabled
*
* OP_MODE: Mode of operation
* OP_MODE_DEEP_SLEEP Deep Sleep (default)
* OP_MODE_2LEAD_GROUND_CELL 2-lead ground referred galvanic cell
* OP_MODE_STANDBY Standby
* OP_MODE_3LEAD_AMP_CELL 3-lead amperometric cell
* OP_MODE_TEMPERATURE_TIA_OFF Temperature measurement (TIA Off)
* OP_MODE_TEMPERATURE_TIA_ON Temperature measurement (TIA On)
*
* For more details, check thge LMP91000 datasheet, chapter 7.6
*/

// Here is an example of a custom configuration:
const sensorType SENSOR_CUSTOM = {
100.0F, // nanoAmperesPerPPM
0, // internalZeroCalibration
ADS_GAIN_4_096V, // adsGain
TIA_GAIN_120_KOHM, // TIA_GAIN_IN_KOHMS
RLOAD_10_OHM, // RLOAD
REF_EXTERNAL, // REF_SOURCE
INTERNAL_ZERO_20_PERCENT, // INTERNAL_ZERO
BIAS_SIGN_NEGATIVE, // BIAS_SIGN
BIAS_0_PERCENT, // BIAS
FET_SHORT_DISABLED, // FET_SHORT
OP_MODE_3LEAD_AMP_CELL, // OP_MODE
};

// Create the sensor object with the custom type
ElectrochemicalGasSensor sensor(SENSOR_CUSTOM);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// Print the reading with 5 digits of precision
Serial.println("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

🔗Vollständiges Beispiel öffnen

examples/customConfig bei Commit c4df54b

→

Öffnen Sie den Serial Monitor mit 115200 Baud. Der Sketch gibt Folgendes aus:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Danach gibt er alle 2,5 Sekunden eine Zeile Sensor reading: aus, gefolgt von einer Zeile mit der Konzentration (fünf Nachkommastellen) und PPM. Dieser Sketch gibt die Beschriftung mit Serial.println() aus, daher steht der Wert in der Zeile darunter. Schlägt begin() fehl, gibt der Sketch ERROR: Can't init the sensor! Check connections! aus und hält an.

Die Felder von sensorType​

sensorType ist eine einfache Struktur, die in der folgenden Reihenfolge befüllt wird. Die Voreinstellungen wie SENSOR_CO sind ebenfalls sensorType-Werte.

FeldTypWas es festlegt
nanoAmperesPerPPMdoubleDie Empfindlichkeit der Zelle in nA pro PPM, aus ihrem Datenblatt. Die Voreinstellungen der Bibliothek für NO2 und O3 verwenden negative Werte.
internalZeroCalibrationdoubleEine zu jeder Messung addierte Spannung, der Wert, den setCustomZeroCalibration() setzt.
adsGainuint8_tDer Vollausschlagsbereich des ADS1115: ADS_GAIN_6_144V, ADS_GAIN_4_096V, ADS_GAIN_2_048V, ADS_GAIN_1_024V, ADS_GAIN_0_512V oder ADS_GAIN_0_256V.
TIA_GAIN_IN_KOHMSuint8_tDie Verstärkung des LMP91000-Verstärkers: TIA_GAIN_EXTERNAL, TIA_GAIN_2_75_KOHM, TIA_GAIN_3_5_KOHM, TIA_GAIN_7_KOHM, TIA_GAIN_14_KOHM, TIA_GAIN_35_KOHM, TIA_GAIN_120_KOHM oder TIA_GAIN_350_KOHM.
RLOADuint8_tDer Lastwiderstand: RLOAD_10_OHM, RLOAD_33_OHM, RLOAD_50_OHM oder RLOAD_100_OHM.
REF_SOURCEuint8_tDie Referenz: REF_INTERNAL oder REF_EXTERNAL. Das Board hat eine externe 2,5-V-Referenz.
INTERNAL_ZEROuint8_tDer interne Nullpunkt als Anteil der Referenz: INTERNAL_ZERO_20_PERCENT, INTERNAL_ZERO_50_PERCENT, INTERNAL_ZERO_67_PERCENT oder INTERNAL_ZERO_BYPASSED.
BIAS_SIGNuint8_tDie Polarität der Vorspannung: BIAS_SIGN_NEGATIVE oder BIAS_SIGN_POSITIVE.
BIASuint8_tDie Vorspannung als Anteil der Referenz, von BIAS_0_PERCENT bis BIAS_24_PERCENT.
FET_SHORTuint8_tFET_SHORT_DISABLED oder FET_SHORT_ENABLED. Laut Kommentar im Sketch muss er deaktiviert sein, damit die Zelle funktioniert.
OP_MODEuint8_tDer Modus des LMP91000: OP_MODE_3LEAD_AMP_CELL für eine Zelle mit 3 Anschlüssen oder OP_MODE_DEEP_SLEEP, OP_MODE_2LEAD_GROUND_CELL, OP_MODE_STANDBY, OP_MODE_TEMPERATURE_TIA_OFF, OP_MODE_TEMPERATURE_TIA_ON.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erstellt das Sensorobjekt für ein Board. Die Adresse bestimmt, wie begin() mit ihm kommuniziert: Bei einer Adresse von 0x30 bis 0x37 wird das Protokoll der ATtiny404-Bridge verwendet; bei jeder anderen Adresse kommuniziert es mit einem ADS1115 an dieser Adresse und direkt mit dem LMP91000. Der Standardwert ist DEFAULT_ADC_ADDR (0x49).

ReturnsKonstruktor.

Parameter

NameTypBeschreibung
_tsensorTypeHier der eigene SENSOR_CUSTOM des Sketches.
_adcAddruint8_tDie Adresse, die begin() verwendet. 0x30 bis 0x37 wählt das Bridge-Protokoll; dieses Board antwortet werkseitig bei 0x30 oder bei der Adresse, die sein Schalter einstellt. Jeder andere Wert wird als ADS1115-Adresse behandelt. Standardmäßig 0x49.
_configPinintEin GPIO für die Enable-Leitung des LMP91000. Die Bibliothek hält ihn auf High und zieht ihn nur dann auf Low, wenn sie selbst die Register des LMP91000 beschreibt; bei einer Adresse von 0x30 bis 0x37 wird er nicht verwendet. Standardmäßig -1 (keiner).
bool begin()returns bool

Startet I2C mit Wire.begin() und wählt das Protokoll anhand der Adresse. Bei 0x30 bis 0x37 prüft es, ob die Bridge antwortet, sendet die ADC-Verstärkung aus der Konfiguration und lässt die Bridge die Register des LMP91000 beschreiben, wobei jeder Schritt nach 500 ms aufgibt. Bei jeder anderen Adresse prüft es, ob ein ADS1115 an dieser Adresse antwortet, stellt dessen Verstärkung ein und beschreibt die Register des LMP91000, sobald dieser Bereitschaft meldet; ist _configPin angegeben, wird er um die Schreibvorgänge herum auf Low gezogen. Rufen Sie es einmal vor dem Lesen auf.

Returnstrue, wenn jeder Schritt erfolgreich war, andernfalls false.

double getPPM()returns double

Nimmt eine Messung von Kanal 0 des ADS1115 auf (bei 0x30 bis 0x37 über die Bridge) und rechnet sie mit der Konfiguration in eine Konzentration um: Sie entfernt den internen Nullpunkt-Offset, addiert die Nullpunktkalibrierung und teilt durch die Verstärkung des Verstärkers und durch die Empfindlichkeit in nA pro PPM. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Gaskonzentration in PPM.

Alles zusammen​

Befüllen Sie einen sensorType mit den Werten aus dem Datenblatt Ihrer Zelle und übergeben Sie ihn an ElectrochemicalGasSensor, wo Sie sonst eine Voreinstellung übergeben würden. begin() sendet seine Einstellungen an den LMP91000, und getPPM() verwendet dessen Empfindlichkeits- und Nullwerte für jede Messung.