Zum Hauptinhalt springen

Einen Sensor in PPM auslesen

Was dieses Beispiel zeigt​

Das Beispiel singleSensor erstellt einen Sensor mit der Voreinstellung für Kohlenmonoxid, SENSOR_CO, startet ihn und gibt die Gaskonzentration in Parts per Million (PPM) alle 2,5 Sekunden aus.

Verbinden Sie Ihren Controller für dieses Beispiel mit der oberen Stiftleiste, nicht mit einem Qwiic- Connector: SDA des Controllers mit SDA2, SCL mit SCL2, die 3,3-V-Versorgung mit 3V3 und Masse mit GND. Bei dieser Adresse kommuniziert die Bibliothek direkt mit dem ADS1115 und dem LMP91000 über SDA2 und SCL2; die ATtiny404-Bridge des Boards bei 0x30 wird nicht verwendet. Über Qwiic funktioniert nur das Bridge-Beispiel in der Kurzanleitung.

Der Beispielcode​

Die Skizze erstellt den Sensor nur mit der Voreinstellung, daher werden die Standardadresse der Bibliothek, 0x49, und kein _configPin verwendet. Ändern Sie SENSOR_CO in die Voreinstellung für Ihre Zelle: SENSOR_NO2, SENSOR_SO2, SENSOR_O3, SENSOR_NO, SENSOR_H2S, SENSOR_NH3 oder SENSOR_CL2.

Der Kommentar in der Skizze besagt, dass LMPEN mit GND oder einem GPIO verbunden werden soll. Auf diesem Board führt LMPEN zur Stiftleiste und zum ATtiny404 des Boards.

Select Board
singleSensor.ino
/**
**************************************************
*
* @file singleSensor.ino
* @brief See how to init one sensor and make a simple reading of PPM of gas.
*
* To successfully run the sketch:
* - Connect LMPEN pin to GND or a GPIO pin so the breakout can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Configurations for each of the sensor types are in sensorConfigData.h in the library's 'src' folder
// Create the sensor object with the according type
ElectrochemicalGasSensor sensor(SENSOR_CO);

// If you are using a custom I2C address (for multiple sensors) use:
// ElectrochemicalGasSensor sensor(SENSOR_SO2, 0x4B, 5);
// For more details on this, see customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

🔗Vollständiges Beispiel öffnen

examples/singleSensor bei Commit c4df54b

→

Öffnen Sie den Serial Monitor mit 115200 Baud. Die Skizze gibt aus:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Danach folgt alle 2,5 Sekunden eine Zeile: Sensor reading: , die Konzentration mit fünf Nachkommastellen und PPM. Schlägt begin() fehl, gibt die Skizze ERROR: Can't init the sensor! Check connections! aus und hält an.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erstellt das Sensorobjekt für ein Board. Die Adresse bestimmt, wie begin() mit ihm kommuniziert: Bei einer Adresse von 0x30 bis 0x37 wird das Protokoll der ATtiny404-Bridge verwendet; bei jeder anderen Adresse kommuniziert es mit einem ADS1115 an dieser Adresse und selbst mit dem LMP91000. Standard ist DEFAULT_ADC_ADDR (0x49).

ReturnsKonstruktor.

Parameter

NameTypBeschreibung
_tsensorTypeDie Voreinstellung für Ihre Zelle: SENSOR_CO, SENSOR_NO2, SENSOR_SO2, SENSOR_O3, SENSOR_NO, SENSOR_H2S, SENSOR_NH3, SENSOR_CL2 oder Ihr eigener sensorType.
_adcAddruint8_tDie Adresse, die begin() verwendet. 0x30 bis 0x37 wählt das Bridge-Protokoll; dieses Board antwortet werkseitig bei 0x30 oder bei der Adresse, die sein Schalter einstellt. Jeder andere Wert wird als ADS1115-Adresse verstanden. Standardmäßig 0x49.
_configPinintEin GPIO für die Enable-Leitung des LMP91000. Die Bibliothek hält ihn auf High und zieht ihn nur dann auf Low, während sie selbst die Register des LMP91000 beschreibt; bei einer Adresse von 0x30 bis 0x37 wird er nicht verwendet. Standardmäßig -1 (keiner).
bool begin()returns bool

Startet I2C mit Wire.begin() und wählt das Protokoll anhand der Adresse. Bei 0x30 bis 0x37 prüft es, ob die Bridge antwortet, sendet die ADC-Verstärkung aus der Voreinstellung und lässt die Bridge die Register des LMP91000 beschreiben, wobei jeder Schritt nach 500 ms aufgegeben wird. Bei jeder anderen Adresse prüft es, ob ein ADS1115 an dieser Adresse antwortet, stellt dessen Verstärkung ein und beschreibt die Register des LMP91000, sobald dieser Bereitschaft meldet; ist _configPin angegeben, wird er während der Schreibvorgänge auf Low gezogen. Rufen Sie es einmal vor dem Auslesen auf.

Returnstrue, wenn jeder Schritt erfolgreich war, sonst false.

double getPPM()returns double

Nimmt eine Messung von Kanal 0 des ADS1115 auf (bei 0x30 bis 0x37 über die Bridge) und rechnet sie mit der Voreinstellung in eine Konzentration um: Sie entfernt den internen Nullpunktversatz, addiert die Nullpunktkalibrierung, teilt durch die Verstärkung des Verstärkers und durch die Empfindlichkeit der Zelle in nA pro PPM. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Gaskonzentration in PPM.

double getPPB()returns double

Dieselbe Messung wie getPPM(), in Parts per Billion.

ReturnsDie Gaskonzentration in PPB, getPPM() x 1000.

Zusammenfassung​

Erstellen Sie einen ElectrochemicalGasSensor mit der Voreinstellung für Ihre Zelle, rufen Sie begin() einmal in setup() auf und halten Sie an, wenn es false zurückgibt. Rufen Sie dann getPPM() oder getPPB() für jede Messung auf.