Zum Hauptinhalt springen

Eigene Front-End-Einstellungen verwenden

Was dieses Beispiel zeigt​

Das Beispiel customConfig erstellt ein eigenes Preset, einen sensorType namens SENSOR_CUSTOM, statt eines der Presets der Bibliothek zu verwenden. Ein Preset enthält die Empfindlichkeit der Zelle, den ADC-Bereich und alle Front-End-Einstellungen des LMP91000. So lassen sich andere Werte für eine Zelle ausprobieren. Der Sketch gibt anschließend alle 2,5 Sekunden einen Messwert in ppm aus.

Das Beispiel erzeugt den Sensor nur mit dem Preset, daher verwendet die Bibliothek ihre Standardadresse DEFAULT_ADC_ADDR (0x49). Bei dieser Adresse kommuniziert die Bibliothek direkt mit dem ADS1115 und dem LMP91000, nicht über die ATtiny404-Bridge des Boards, und der Header des Sketches verlangt, dass LMPEN mit einem GPIO verbunden ist. Siehe die Bibliotheksübersicht, wie die Adresse dies bestimmt.

Für die SGX-4NO-250-Zelle dieses Boards verwendet das bibliothekseigene Preset SENSOR_NO die Werte in der folgenden Tabelle. Das SENSOR_CUSTOM des Beispiels unterscheidet sich davon in der Empfindlichkeit (100 nA pro ppm) und der Vorspannung (negativ, 0 %).

FeldWert von SENSOR_NO
nanoAmperesPerPPM400.0F
internalZeroCalibration0
adsGainADS_GAIN_4_096V
TIA_GAIN_IN_KOHMSTIA_GAIN_120_KOHM
RLOADRLOAD_10_OHM
REF_SOURCEREF_EXTERNAL
INTERNAL_ZEROINTERNAL_ZERO_20_PERCENT
BIAS_SIGNBIAS_SIGN_POSITIVE
BIASBIAS_12_PERCENT
FET_SHORTFET_SHORT_DISABLED
OP_MODEOP_MODE_3LEAD_AMP_CELL

Der Beispielcode​

Das Listing ist die Datei der Bibliothek beim fixierten Commit. Nur Kommentarzeilen wurden weggelassen: die Zeile, die den alten Connector nennt, und die Header-Zeilen, die auf die Shopseiten anderer Produkte verlinken.

Select Board
customConfig.ino
/**
**************************************************
*
* @file customConfig.ino
* @brief Create a custom config for the LMP91000 and upload it to the device.
* This enables you to use this breakout with any electrochemical sensor.
*
* To successfully run the sketch:
* - Edit the custom configuration
* - Connect LMPEN to any GPIO pin
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

/**
* Here are parameters to configure for the custom sensor:
*
* nanoAmperesPerPPM: From the datasheet of the particular electrochemical
* sensor, used in the calculation of PPM/PPB
*
* internalZeroCalibration: A fixed value which is summed to the voltage
* measured by the ADS. The value here should make the reading be
* just barely 0 PPM when the sensor is in a place with none of the target gas
*
* adsGain: The gain of the ADS
* The voltage here represents the max range which it can measure
* ADS_GAIN_6_144V 6.144 V
* ADS_GAIN_4_096V 4.096 V
* ADS_GAIN_2_048V 2.048 V
* ADS_GAIN_1_024V 1.024 V
* ADS_GAIN_0_512V 0.512 V
* ADS_GAIN_0_256V 0.256 V
*
* TIA_GAIN_IN_KOHMS: The gain of the amplifier
* This increases the sensitivity of the measurement
* TIA_GAIN_EXTERNAL External resistance
* TIA_GAIN_2_75_KOHM 2.75 kOhm
* TIA_GAIN_3_5_KOHM 3.5 kOhm
* TIA_GAIN_7_KOHM 7 kOhm
* TIA_GAIN_14_KOHM 14 kOhm
* TIA_GAIN_35_KOHM 35 kOhm
* TIA_GAIN_120_KOHM 120 kOhm
* TIA_GAIN_350_KOHM 350 kOhm
*
* RLOAD: The load resistor in the LMP91000
* Specified in the electrochemical sensor's datasheet
* RLOAD_10_OHM 10 Ohm
* RLOAD_33_OHM 33 Ohm
* RLOAD_50_OHM 50 Ohm
* RLOAD_100_OHM 100 Ohm
*
* REF_SOURCE: Source of the control voltage reference
* For our breakout, use external, there's a 2.5V external
* reference voltage
* REF_INTERNAL Internal
* REF_EXTERNAL External
*
* INTERNAL_ZERO: Internal zero selection
* If the electrochemical sensor has a positive polarity, you
* would usually want to use 20% for the most headroom in the signal
* INTERNAL_ZERO_20_PERCENT 20%
* INTERNAL_ZERO_50_PERCENT 50%
* INTERNAL_ZERO_67_PERCENT 67%
* INTERNAL_ZERO_BYPASSED Internal zero bypassed
*
* BIAS_SIGN: The polarity of the bias voltage
* BIAS_SIGN_NEGATIVE Negative
* BIAS_SIGN_POSITIVE Positive
*
* BIAS: Added bias, percentage of the reference voltage
* Most sensors don't require this, check each sensor's datasheet
* BIAS_0_PERCENT 0%
* BIAS_1_PERCENT 1%
* BIAS_2_PERCENT 2%
* BIAS_4_PERCENT 4%
* BIAS_6_PERCENT 6%
* ...
* BIAS_22_PERCENT 22%
* BIAS_24_PERCENT 24%
*
* FET_SHORT: Short the FET
* Used to perserve the electrochemical sensor
* Has to be disabled for the sensor to be operable
* FET_SHORT_DISABLED Disabled
* FET_SHORT_ENABLED Enabled
*
* OP_MODE: Mode of operation
* OP_MODE_DEEP_SLEEP Deep Sleep (default)
* OP_MODE_2LEAD_GROUND_CELL 2-lead ground referred galvanic cell
* OP_MODE_STANDBY Standby
* OP_MODE_3LEAD_AMP_CELL 3-lead amperometric cell
* OP_MODE_TEMPERATURE_TIA_OFF Temperature measurement (TIA Off)
* OP_MODE_TEMPERATURE_TIA_ON Temperature measurement (TIA On)
*
* For more details, check thge LMP91000 datasheet, chapter 7.6
*/

// Here is an example of a custom configuration:
const sensorType SENSOR_CUSTOM = {
100.0F, // nanoAmperesPerPPM
0, // internalZeroCalibration
ADS_GAIN_4_096V, // adsGain
TIA_GAIN_120_KOHM, // TIA_GAIN_IN_KOHMS
RLOAD_10_OHM, // RLOAD
REF_EXTERNAL, // REF_SOURCE
INTERNAL_ZERO_20_PERCENT, // INTERNAL_ZERO
BIAS_SIGN_NEGATIVE, // BIAS_SIGN
BIAS_0_PERCENT, // BIAS
FET_SHORT_DISABLED, // FET_SHORT
OP_MODE_3LEAD_AMP_CELL, // OP_MODE
};

// Create the sensor object with the custom type
ElectrochemicalGasSensor sensor(SENSOR_CUSTOM);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// Print the reading with 5 digits of precision
Serial.println("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis, wenn SENSOR_CUSTOM auf die Werte von SENSOR_NO gesetzt ist (Messwerte in sauberer Luft; Ihre werden abweichen):

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!
Sensor reading:
0.00610 PPM
Sensor reading:
0.00601 PPM
Sensor reading:
0.00600 PPM
Sensor reading:
0.00614 PPM

Alle 2,5 Sekunden erscheint eine Zeile Sensor reading: und, in der nächsten Zeile, die Konzentration in ppm mit fünf Nachkommastellen und PPM am Ende: Der Sketch gibt das Label mit Serial.println() aus, daher beginnt der Wert in einer neuen Zeile. Schlägt begin() fehl, gibt der Sketch ERROR: Can't init the sensor! Check connections! aus und hält dort an.

Verwendete Funktionen​

sensorTypereturns sensorType

Die Struktur, die ein Preset enthält. Ihre Felder in dieser Reihenfolge: nanoAmperesPerPPM, internalZeroCalibration, adsGain, TIA_GAIN_IN_KOHMS, RLOAD, REF_SOURCE, INTERNAL_ZERO, BIAS_SIGN, BIAS, FET_SHORT und OP_MODE. Die Presets der Bibliothek, etwa SENSOR_NO, sind sensorType-Werte in sensorConfigData.h. begin() sendet die Front-End-Felder an den LMP91000 und die Verstärkung an den ADC; getPPM() verwendet die Empfindlichkeit und die Nullpunktkalibrierung.

ReturnsDas Preset, das Sie an ElectrochemicalGasSensor übergeben.

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Erzeugt das Sensorobjekt für ein Board. Über I2C wird nichts gesendet, bis Sie begin() aufrufen.

ReturnsDas Sensorobjekt.

Parameter

TypNameBeschreibung
sensorType_tDas Preset, im Beispiel SENSOR_CUSTOM.
uint8_t_adcAddrDie I2C-Adresse. Im Beispiel weggelassen, daher DEFAULT_ADC_ADDR, 0x49. Bei einer Adresse von 0x30 bis 0x37 kommuniziert die Bibliothek mit der ATtiny404-Bridge des Boards; bei jeder anderen kommuniziert sie mit dem ADS1115 an dieser Adresse und direkt mit dem LMP91000.
int_configPinDer mit LMPEN verbundene GPIO. Im Beispiel weggelassen (-1), daher schaltet die Bibliothek keinen Pin.
sensor.begin()returns bool

Startet I2C mit Wire.begin(). Bei einer Adresse von 0x30 bis 0x37 prüft es, ob die Bridge des Boards antwortet, und sendet die ADC- und Front-End-Einstellungen darüber, wobei es pro Schritt bis zu 500 ms wartet. Bei jeder anderen Adresse startet es den ADS1115 an dieser Adresse mit der Verstärkung des Presets und der langsamsten Datenrate und konfiguriert dann den LMP91000 (Verstärkung, Last, Referenz, interner Nullpunkt, Vorspannung und Modus). Ist ein _configPin-GPIO angegeben, hält es diesen dabei auf LOW.

Returnstrue, wenn jeder Schritt erfolgreich war, andernfalls false.

sensor.getPPM()returns double

Nimmt einen ADC-Messwert auf und rechnet ihn um: Es zieht den internen Nullpunkt ab (2,5 V mal den Prozentwert des internen Nullpunkts des Presets), addiert die Nullpunktkalibrierung, teilt durch die Verstärkung des Verstärkers, um den Zellenstrom zu erhalten, und teilt diesen durch die nA pro ppm des Presets.

ReturnsDie Gaskonzentration in ppm. Ein negatives Ergebnis wird als 0 zurückgegeben.

Alles zusammen​

Das Preset sind reine Daten: Definieren Sie es einmal, übergeben Sie es dem Konstruktor, und begin() sendet dessen Front-End-Einstellungen, wenn es den Sensor startet. Um andere Werte auszuprobieren, bearbeiten Sie die Felder von SENSOR_CUSTOM und laden den Sketch erneut hoch.