Zum Hauptinhalt springen

NO2-Konzentration auslesen

Was dieses Beispiel zeigt​

Das Beispiel bridgeBoard der Bibliothek erstellt den Sensor mit der I2C-Adresse des Boards, startet ihn und gibt die Gaskonzentration alle 2,5 Sekunden in ppm aus. Eine Adresse von 0x30 bis 0x37 teilt der Bibliothek mit, dass sie mit dem ATtiny404 des Boards kommuniziert, der den LMP91000 und den ADS1115 für Sie steuert.

Das Beispiel erstellt den Sensor mit dem Preset für Kohlenmonoxid, SENSOR_CO. Ändern Sie SENSOR_CO in SENSOR_NO2, bevor Sie es hochladen: SENSOR_NO2 ist das Preset der Bibliothek für die SGX-4NO2-Zelle auf diesem Board. Wenn Sie die ADDRESS-Schalter verstellt haben, ändern Sie 0x30 in die Adresse, die diese einstellen.

Der Beispielcode​

Select Board
bridgeBoard.ino
/**
**************************************************
*
* @file bridgeBoard.ino
* @brief See how to init a sensor on the new ATtiny404 bridge board revision,
*
* To successfully run the sketch:
* - Set the desired address using the jumpers on the back of the board
* (address = 0x30 + jumper offset, giving a range of 0x30-0x37)
* - Run the sketch and open serial monitor at 115200 baud!
*
* Note: on this board revision, LMPEN is hardwired to GND, so there's
* no configPin argument to pass - the constructor's third argument
* is ignored whenever the address falls in the bridge range (0x30-0x37).
*
*
* @authors @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Any additional boards on the same bus just need a different jumper setting
// (0x30-0x37), same as twoSensors.ino does for legacy boards with 0x49/0x4A/0x4B.
ElectrochemicalGasSensor sensor(SENSOR_CO, 0x30);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections and jumper address!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Der Kommentar am Anfang des Beispiels besagt, dass LMPEN fest mit GND verbunden ist. Auf diesem Board ist LMPEN der Enable-Eingang des LMP91000 und zusätzlich mit dem ATtiny404 verbunden, wie Hardware-Details zeigt. In beiden Fällen schließen Sie nichts daran an: Bei den Adressen 0x30 bis 0x37 verwendet die Bibliothek das dritte Argument des Konstruktors nicht.

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!
Sensor reading: 0.01453 PPM
Sensor reading: 0.01357 PPM
Sensor reading: 0.01379 PPM
Sensor reading: 0.01435 PPM

Alle 2,5 Sekunden folgt eine neue Zeile Sensor reading: mit der NO2-Konzentration in ppm mit fünf Nachkommastellen. Antwortet das Board nicht, gibt es ERROR: Can't init the sensor! Check connections and jumper address! aus und hält an.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Erstellt das Sensorobjekt. Bis zum Aufruf von begin() wird nichts an das Board gesendet. Die Adresse bestimmt, wie begin() mit dem Board kommuniziert: Von 0x30 bis 0x37 sendet es seine Befehle an den ATtiny404, und von 0x48 bis 0x4B (DEFAULT_ADC_ADDR ist 0x49) spricht es den ADS1115 unter dieser Adresse und den LMP91000 direkt an.

ReturnsDas Sensorobjekt.

Parameter

TypNameBeschreibung
sensorType_tDas Preset der Zelle. Verwenden Sie SENSOR_NO2 für die SGX-4NO2-Zelle dieses Boards.
uint8_t_adcAddrDie I2C-Adresse des Boards. Verwenden Sie 0x30 bis 0x37, wie von den ADDRESS-Schaltern eingestellt; im Auslieferungszustand 0x30.
int_configPinGPIO für den Enable-Pin des LMP91000. Wird bei den Adressen 0x30 bis 0x37 nicht verwendet; lassen Sie ihn weg.
sensor.begin()returns bool

Startet Wire, prüft, ob das Board antwortet, und sendet ihm dann die ADC-Verstärkung und die Datenrate sowie die LMP91000-Konfiguration aus dem Preset. Jeder Schritt wartet bis zu 500 ms auf die Antwort des Boards. Rufen Sie es einmal in setup() auf.

Returnstrue, wenn jeder Schritt erfolgreich war, sonst false.

sensor.getPPM()returns double

Fordert vom Board einen neuen ADC-Messwert an und rechnet ihn in eine Gaskonzentration um: Spannung minus internem Nullpunkt, plus Kalibrierungs-Offset, geteilt durch die TIA-Verstärkung und durch die Empfindlichkeit der Zelle aus dem Preset. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Gaskonzentration in ppm.

sensor.getPPB()returns double

Derselbe Messwert wie bei getPPM(), multipliziert mit 1000. Das Beispiel erwähnt ihn in einem Kommentar als die Zeile, die Sie verwenden, wenn Teile pro Milliarde für Ihren Sensor besser geeignet sind.

ReturnsDie Gaskonzentration in ppb.

Zusammenspiel​

begin() läuft einmal in setup(). Schlägt es fehl, gibt der Sketch den Fehler aus und bleibt in einer Endlosschleife, sodass nichts anderes mehr läuft, bis Sie die Verbindung oder die Adresse korrigieren und das Board zurücksetzen. In loop() liest jeder Aufruf von getPPM() die Zelle erneut aus, und der Sketch gibt den Wert mit fünf Nachkommastellen aus.