Zum Hauptinhalt springen

Gaskonzentration auslesen

Was dieses Beispiel zeigt​

Das Beispiel singleSensor der Bibliothek erstellt den Sensor, startet ihn und gibt die Gaskonzentration in ppm alle 2,5 Sekunden aus.

Das Beispiel erstellt den Sensor mit der Voreinstellung für Kohlenmonoxid, SENSOR_CO. SENSOR_NO2 ist die Voreinstellung der Bibliothek für die SGX-4NO2-Zelle dieses Boards; ändern Sie sie in der Zeile, die den Sensor erstellt.

Der Beispielcode​

Select Board
singleSensor.ino
/**
**************************************************
*
* @file singleSensor.ino
* @brief See how to init one sensor and make a simple reading of PPM of gas.
*
* To successfully run the sketch:
* - Connect LMPEN pin to GND or a GPIO pin so the breakout can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Configurations for each of the sensor types are in sensorConfigData.h in the library's 'src' folder
// Create the sensor object with the according type
ElectrochemicalGasSensor sensor(SENSOR_CO);

// If you are using a custom I2C address (for multiple sensors) use:
// ElectrochemicalGasSensor sensor(SENSOR_SO2, 0x4B, 5);
// For more details on this, see customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Danach gibt der Sketch alle 2,5 Sekunden eine Zeile aus, die mit Sensor reading: beginnt, gefolgt von der Konzentration in ppm mit fünf Nachkommastellen. Wenn begin() fehlschlägt, gibt er ERROR: Can't init the sensor! Check connections! aus und hält an.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Erstellt das Sensorobjekt. Es wird nichts an das Board gesendet, bis Sie begin() aufrufen. Die Adresse bestimmt, wie begin() mit dem Board kommuniziert: Von 0x30 bis 0x37 sendet es seine Befehle an den ATtiny404, und von 0x48 bis 0x4B (DEFAULT_ADC_ADDR ist 0x49) spricht es den ADS1115 und den LMP91000 an dieser Adresse direkt an.

ReturnsDas Sensorobjekt.

Parameter

TypNameBeschreibung
sensorType_tDie Voreinstellung der Zelle. SENSOR_NO2 ist die Voreinstellung für die SGX-4NO2-Zelle dieses Boards; das Beispiel übergibt SENSOR_CO.
uint8_t_adcAddrDie Adresse, mit der begin() kommuniziert, standardmäßig 0x49; das Beispiel belässt sie beim Standardwert.
int_configPinGPIO für den Enable-Pin des LMP91000 (LMPEN), nur bei 0x48 bis 0x4B verwendet. Standardmäßig -1 (keiner); das Beispiel übergibt keinen.
sensor.begin()returns bool

Startet Wire und schreibt die Voreinstellung auf das Board. Von 0x30 bis 0x37 prüft es, ob der ATtiny404 antwortet, und sendet ihm dann die ADC-Verstärkung und die Datenrate sowie die Konfiguration des LMP91000, wobei jeder Schritt bis zu 500 ms auf die Antwort wartet. Von 0x48 bis 0x4B startet es den ADS1115 an dieser Adresse, stellt die Verstärkung der Voreinstellung und die langsamste Datenrate ein und schreibt die Konfiguration des LMP91000; dabei zieht es _configPin auf Low, sofern einer angegeben ist. Rufen Sie es einmal in setup() auf.

Returnstrue, wenn jeder Schritt erfolgreich war, andernfalls false.

sensor.getPPM()returns double

Nimmt einen neuen ADC-Messwert auf und wandelt ihn in eine Gaskonzentration um: die Spannung abzüglich des internen Nullpunkts, zuzüglich des Kalibrierungsoffsets, geteilt durch die TIA-Verstärkung und durch die Empfindlichkeit der Zelle in der Voreinstellung. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Gaskonzentration in ppm.

sensor.getPPB()returns double

Derselbe Messwert wie bei getPPM(), multipliziert mit 1000. Das Beispiel erwähnt sie in einem Kommentar als die Zeile, die man verwendet, wenn Parts per Billion für Ihren Sensor besser geeignet sind.

ReturnsDie Gaskonzentration in ppb.

Zusammenspiel​

begin() wird einmal in setup() ausgeführt. Schlägt der Aufruf fehl, gibt der Sketch den Fehler aus und bleibt in einer Endlosschleife. In loop() liest jeder Aufruf von getPPM() die Zelle erneut aus, und der Sketch gibt den Wert mit fünf Nachkommastellen aus und wartet 2,5 Sekunden.