Zum Hauptinhalt springen

Zwei Sensoren an einem Bus auslesen

Was dieses Beispiel zeigt​

Das twoSensors-Beispiel der Bibliothek liest zwei Boards an einem I2C-Bus aus. Es erstellt pro Board ein Sensorobjekt, startet beide und gibt alle 2,5 Sekunden einen Kohlenmonoxid-Messwert in ppm und einen NO2-Messwert in ppb aus.

Das Beispiel erstellt sensorCO mit dem Preset SENSOR_CO an Adresse 0x4A mit LMPEN an GPIO 25 und sensorNO2 mit dem Preset SENSOR_NO2, dem Preset der Bibliothek für die SGX-4NO2-Zelle dieses Boards, an Adresse 0x49 mit LMPEN an GPIO 32.

Der Beispielcode​

Select Board
twoSensors.ino
/**
**************************************************
*
* @file twoSensors.ino
* @brief See how to init two sensors and make two readings of PPM of gas.
*
* To successfully run the sketch:
* - Set different addresses using the jumpers on the back of the breakout
* - Connect LMPEN pins to a GPIO pin so the breakouts can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Create two different sensor objects
ElectrochemicalGasSensor sensorCO(SENSOR_CO, 0x4A, 25);
ElectrochemicalGasSensor sensorNO2(SENSOR_NO2, 0x49, 32);
// To see how the custom addresses are determined, check customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init breakout #1
if (!sensorCO.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("CO sensor initialized successfully!");

// Init breakout #2
if (!sensorNO2.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("NO2 sensor initialized successfully!");
}

void loop()
{
// Make the reading of CO and print it
double COreading = sensorCO.getPPM();

// Print the reading with 5 digits of precision
Serial.print("CO sensor reading: ");
Serial.print(COreading, 5);
Serial.println(" PPM");

// Make the reading of NO2 and print it
double NO2reading = sensorNO2.getPPB();

// Print the reading with 5 digits of precision
Serial.print("NO2 sensor reading: ");
Serial.print(NO2reading, 5);
Serial.println(" PPB");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
CO sensor initialized successfully!
NO2 sensor initialized successfully!

Danach gibt der Sketch alle 2,5 Sekunden zwei Zeilen aus: eine, die mit CO sensor reading: beginnt, gefolgt von dieser Konzentration in ppm, und eine, die mit NO2 sensor reading: beginnt, gefolgt von der NO2-Konzentration in ppb, jeweils mit fünf Nachkommastellen. Wenn einer der Sensoren nicht startet, gibt der Sketch ERROR: Can't init the sensor! Check connections! aus und hält an.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Erstellt ein Sensorobjekt. Es wird nichts an das Board gesendet, bis Sie begin() aufrufen. Die Adresse bestimmt, wie begin() mit dem Board kommuniziert: Von 0x30 bis 0x37 sendet es seine Befehle an den ATtiny404, und von 0x48 bis 0x4B (DEFAULT_ADC_ADDR ist 0x49) spricht es den ADS1115 und den LMP91000 an dieser Adresse direkt an. Das Beispiel erstellt zwei, eines pro Board.

ReturnsDas Sensorobjekt.

Parameter

TypNameBeschreibung
sensorType_tDas Preset der Zelle. Das Beispiel übergibt SENSOR_CO und SENSOR_NO2, das Preset für die SGX-4NO2-Zelle dieses Boards.
uint8_t_adcAddrDie Adresse, mit der begin() kommuniziert, standardmäßig 0x49; das Beispiel übergibt 0x4A und 0x49.
int_configPinGPIO für den Enable-Pin des LMP91000 (LMPEN), nur bei 0x48 bis 0x4B verwendet. Standardmäßig -1 (keiner); das Beispiel übergibt 25 und 32.
sensor.begin()returns bool

Startet Wire und schreibt das Preset auf ein Board. Von 0x30 bis 0x37 prüft es, ob der ATtiny404 antwortet, und sendet ihm dann die ADC-Verstärkung und die Datenrate sowie die LMP91000-Konfiguration, wobei jeder Schritt bis zu 500 ms auf die Antwort wartet. Von 0x48 bis 0x4B startet es den ADS1115 an dieser Adresse, setzt die Verstärkung des Presets und die langsamste Datenrate und schreibt die LMP91000-Konfiguration, wobei es _configPin auf LOW zieht, wenn einer angegeben ist. Rufen Sie es in setup() einmal für jeden Sensor auf.

Returnstrue, wenn alle Schritte erfolgreich waren, sonst false.

sensor.getPPM()returns double

Nimmt einen neuen ADC-Messwert von einem Sensor auf und wandelt ihn in eine Gaskonzentration um: die Spannung minus den internen Nullpunkt, plus den Kalibrierungsoffset, geteilt durch die TIA-Verstärkung und durch die Empfindlichkeit der Zelle im Preset. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Gaskonzentration in ppm.

sensor.getPPB()returns double

Derselbe Messwert wie bei getPPM(), multipliziert mit 1000. Das Beispiel liest den NO2-Sensor damit aus.

ReturnsDie Gaskonzentration in ppb.

Zusammenspiel​

Beide Sensorobjekte werden erstellt, bevor setup() ausgeführt wird, und unterscheiden sich in Preset, Adresse und LMPEN-Pin. setup() startet sensorCO, dann sensorNO2, und bleibt bei dem ersten, der fehlschlägt, in einer Endlosschleife hängen. Bei jedem Durchlauf liest loop() sensorCO mit getPPM() und sensorNO2 mit getPPB() aus, gibt beide Werte mit fünf Nachkommastellen aus und wartet 2,5 Sekunden.