Zum Hauptinhalt springen

Benutzerdefinierte Konfiguration

Was dieses Beispiel zeigt​

Das Beispiel customConfig erstellt einen eigenen sensorType, SENSOR_CUSTOM, statt eine Voreinstellung zu verwenden, übergibt ihn dem Konstruktor und gibt alle 2,5 Sekunden einen Messwert in PPM aus. Der Kommentarblock im Beispiel listet jede Einstellung auf und die Werte, die sie jeweils annimmt; hier tragen Sie die Einstellungen Ihrer eigenen Zelle ein. Der Sensor wird ohne Adresse erstellt, daher verwendet der Konstruktor seine Standardadresse, DEFAULT_ADC_ADDR (0x49).

Sie müssen LMPEN auf diesem Board nicht verdrahten, auch wenn es in den Kommentaren des Sketches anders steht: Das Board hält den Pin selbst auf Low.

Der Beispielcode​

Select Board
customConfig.ino
/**
**************************************************
*
* @file customConfig.ino
* @brief Create a custom config for the LMP91000 and upload it to the device.
* This enables you to use this breakout with any electrochemical sensor.
*
* To successfully run the sketch:
* - Edit the custom configuration
* - Connect LMPEN to any GPIO pin
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

/**
* Here are parameters to configure for the custom sensor:
*
* nanoAmperesPerPPM: From the datasheet of the particular electrochemical
* sensor, used in the calculation of PPM/PPB
*
* internalZeroCalibration: A fixed value which is summed to the voltage
* measured by the ADS. The value here should make the reading be
* just barely 0 PPM when the sensor is in a place with none of the target gas
*
* adsGain: The gain of the ADS
* The voltage here represents the max range which it can measure
* ADS_GAIN_6_144V 6.144 V
* ADS_GAIN_4_096V 4.096 V
* ADS_GAIN_2_048V 2.048 V
* ADS_GAIN_1_024V 1.024 V
* ADS_GAIN_0_512V 0.512 V
* ADS_GAIN_0_256V 0.256 V
*
* TIA_GAIN_IN_KOHMS: The gain of the amplifier
* This increases the sensitivity of the measurement
* TIA_GAIN_EXTERNAL External resistance
* TIA_GAIN_2_75_KOHM 2.75 kOhm
* TIA_GAIN_3_5_KOHM 3.5 kOhm
* TIA_GAIN_7_KOHM 7 kOhm
* TIA_GAIN_14_KOHM 14 kOhm
* TIA_GAIN_35_KOHM 35 kOhm
* TIA_GAIN_120_KOHM 120 kOhm
* TIA_GAIN_350_KOHM 350 kOhm
*
* RLOAD: The load resistor in the LMP91000
* Specified in the electrochemical sensor's datasheet
* RLOAD_10_OHM 10 Ohm
* RLOAD_33_OHM 33 Ohm
* RLOAD_50_OHM 50 Ohm
* RLOAD_100_OHM 100 Ohm
*
* REF_SOURCE: Source of the control voltage reference
* For our breakout, use external, there's a 2.5V external
* reference voltage
* REF_INTERNAL Internal
* REF_EXTERNAL External
*
* INTERNAL_ZERO: Internal zero selection
* If the electrochemical sensor has a positive polarity, you
* would usually want to use 20% for the most headroom in the signal
* INTERNAL_ZERO_20_PERCENT 20%
* INTERNAL_ZERO_50_PERCENT 50%
* INTERNAL_ZERO_67_PERCENT 67%
* INTERNAL_ZERO_BYPASSED Internal zero bypassed
*
* BIAS_SIGN: The polarity of the bias voltage
* BIAS_SIGN_NEGATIVE Negative
* BIAS_SIGN_POSITIVE Positive
*
* BIAS: Added bias, percentage of the reference voltage
* Most sensors don't require this, check each sensor's datasheet
* BIAS_0_PERCENT 0%
* BIAS_1_PERCENT 1%
* BIAS_2_PERCENT 2%
* BIAS_4_PERCENT 4%
* BIAS_6_PERCENT 6%
* ...
* BIAS_22_PERCENT 22%
* BIAS_24_PERCENT 24%
*
* FET_SHORT: Short the FET
* Used to perserve the electrochemical sensor
* Has to be disabled for the sensor to be operable
* FET_SHORT_DISABLED Disabled
* FET_SHORT_ENABLED Enabled
*
* OP_MODE: Mode of operation
* OP_MODE_DEEP_SLEEP Deep Sleep (default)
* OP_MODE_2LEAD_GROUND_CELL 2-lead ground referred galvanic cell
* OP_MODE_STANDBY Standby
* OP_MODE_3LEAD_AMP_CELL 3-lead amperometric cell
* OP_MODE_TEMPERATURE_TIA_OFF Temperature measurement (TIA Off)
* OP_MODE_TEMPERATURE_TIA_ON Temperature measurement (TIA On)
*
* For more details, check thge LMP91000 datasheet, chapter 7.6
*/

// Here is an example of a custom configuration:
const sensorType SENSOR_CUSTOM = {
100.0F, // nanoAmperesPerPPM
0, // internalZeroCalibration
ADS_GAIN_4_096V, // adsGain
TIA_GAIN_120_KOHM, // TIA_GAIN_IN_KOHMS
RLOAD_10_OHM, // RLOAD
REF_EXTERNAL, // REF_SOURCE
INTERNAL_ZERO_20_PERCENT, // INTERNAL_ZERO
BIAS_SIGN_NEGATIVE, // BIAS_SIGN
BIAS_0_PERCENT, // BIAS
FET_SHORT_DISABLED, // FET_SHORT
OP_MODE_3LEAD_AMP_CELL, // OP_MODE
};

// Create the sensor object with the custom type
ElectrochemicalGasSensor sensor(SENSOR_CUSTOM);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// Print the reading with 5 digits of precision
Serial.println("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Was dieses Board mit dem Sketch in der vorliegenden Form ausgibt, wurde noch nicht gemessen. Beim Test dieses Boards über Qwiic fand ein I2C-Scan nur eine Adresse, 0x30, und mit der MicroPython-Bibliothek schlug begin() für einen Sensor fehl, der mit 0x49 erstellt wurde, der Standardadresse, die dieser Sketch verwendet. Schlägt begin() fehl, gibt der Sketch ERROR: Can't init the sensor! Check connections! aus und hält an.

Wenn begin() erfolgreich ist, gibt der Sketch Folgendes aus:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Danach gibt der Sketch alle 2,5 Sekunden eine Zeile Sensor reading: aus, und in der nächsten Zeile einen Wert mit fünf Nachkommastellen und PPM.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Erstellt das Sensorobjekt mit einer Sensorkonfiguration, einer Adresse und einem LMPEN-Pin. Es wird nichts gesendet, bis Sie begin() aufrufen. begin() wählt anhand der Adresse, wie mit dem Board kommuniziert wird: Von 0x30 bis 0x37 verwendet es die Befehle der ATtiny404-Bridge und ignoriert das dritte Argument; jede andere Adresse wird als eigene Adresse des ADS1115 aufgefasst, und der LMP91000 wird direkt beschrieben.

ReturnsDas Sensorobjekt.

Parameter

TypNameBeschreibung
sensorType_tDie zu verwendende Konfiguration, im Beispiel SENSOR_CUSTOM.
uint8_t_adcAddrDie Adresse, DEFAULT_ADC_ADDR (0x49), wenn sie weggelassen wird, wie im Beispiel.
int_configPinDer GPIO-Pin, der mit LMPEN verbunden ist, -1 (keiner), wenn er weggelassen wird. Wird für eine Adresse von 0x30 bis 0x37 nicht verwendet.
sensor.begin()returns bool

Startet I2C mit Wire.begin(). Bei einer Adresse von 0x30 bis 0x37 prüft es, ob die Bridge antwortet, sendet ihr die ADC-Verstärkung und die langsamste ADC-Datenrate und anschließend die aus dem sensorType erzeugten LMP91000-Einstellungen; jeder Bridge-Befehl wartet bis zu 500 ms. Bei jeder anderen Adresse startet es den ADS1115 unter dieser Adresse mit derselben Verstärkung und Datenrate, setzt den LMPEN-Pin auf High, falls einer angegeben wurde, und schreibt dann die LMP91000-Einstellungen, wobei es diesen Pin währenddessen auf Low hält.

Returnstrue, wenn jeder Schritt erfolgreich war, andernfalls false.

sensor.getPPM()returns double

Führt eine ADC-Messung durch und wandelt die Spannung in eine Konzentration um: Es subtrahiert den internen Nullpunkt (einen Anteil der 2,5-V-Referenz), addiert internalZeroCalibration, teilt durch die TIA-Verstärkung, um den Zellenstrom zu erhalten, und teilt dann durch nanoAmperesPerPPM. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Konzentration in PPM.

Zusammenführung​

Die Werte im SENSOR_CUSTOM des Listings sind die eigenen Platzhalter des Beispiels, keine Einstellungen für die Sauerstoffzelle SGX-4OX-ROHS dieses Boards. Deren BIAS_0_PERCENT legt keine Vorspannung an, die Zelle benötigt aber eine, ändern Sie also die Konfiguration, bevor Sie sie mit diesem Board verwenden:

  • Die Zelle benötigt eine Vorspannung von −600 mV. Mit der 2,5-V-Referenz des Boards ist das BIAS_SIGN_NEGATIVE mit BIAS_24_PERCENT (24 % von 2,5 V sind 0,6 V): Setzen Sie BIAS_24_PERCENT anstelle von BIAS_0_PERCENT aus dem Listing ein.
  • Behalten Sie REF_EXTERNAL bei: Das Board hat eine externe 2,5-V-Referenz.
  • Der Ausgang der Zelle in Luft beträgt 0,1 ± 0,03 mA, und er ist logarithmisch, S = K ln(1/(1-C)), daher rechnet die lineare PPM-Berechnung der Bibliothek ihn nicht direkt in % vol um.

Nach dem Einschalten kann die Zelle bis zu 15 Minuten brauchen, um sich einzupendeln. Lassen Sie sie daher laufen, bevor Sie einem Messwert vertrauen.