Zum Hauptinhalt springen

Den Sensor auslesen

Was dieses Beispiel zeigt​

Das Beispiel bridgeBoard startet das Board über seinen ATtiny404 unter 0x30, sendet dem Analog-Frontend seine Einstellungen und gibt alle 2,5 Sekunden einen Messwert aus. Ihr Controller kommuniziert ausschließlich mit dem ATtiny404; dieser leitet die Einstellungen an den LMP91000 weiter und liest für Sie den ADS1115 aus.

Verbinden Sie das Board mit einem Qwiic-Kabel, oder verdrahten Sie 3V3, GND, SDA1 und SCL1 von der oberen Stiftleiste. LMPEN müssen Sie nicht verdrahten: Das Board hält diesen Pin selbst auf Low. Wo die Kommentare des Sketches Adress-Jumper auf der Rückseite des Boards erwähnen, verwendet dieses Board stattdessen den dreistufigen ADDRESS-Schalter auf seiner Oberseite.

Der Beispielcode​

Select Board
bridgeBoard.ino
/**
**************************************************
*
* @file bridgeBoard.ino
* @brief See how to init a sensor on the new ATtiny404 bridge board revision,
*
* To successfully run the sketch:
* - Set the desired address using the jumpers on the back of the board
* (address = 0x30 + jumper offset, giving a range of 0x30-0x37)
* - Run the sketch and open serial monitor at 115200 baud!
*
* Note: on this board revision, LMPEN is hardwired to GND, so there's
* no configPin argument to pass - the constructor's third argument
* is ignored whenever the address falls in the bridge range (0x30-0x37).
*
*
* @authors @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Any additional boards on the same bus just need a different jumper setting
// (0x30-0x37), same as twoSensors.ino does for legacy boards with 0x49/0x4A/0x4B.
ElectrochemicalGasSensor sensor(SENSOR_CO, 0x30);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections and jumper address!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Danach erscheint alle 2,5 Sekunden eine Zeile Sensor reading: gefolgt von einem Wert mit fünf Nachkommastellen und PPM. Wenn das Board nicht antwortet, gibt der Sketch ERROR: Can't init the sensor! Check connections and jumper address! aus und stoppt.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Erstellt das Sensorobjekt mit einer Sensorkonfiguration und einer Adresse. Bis zum Aufruf von begin() wird nichts an das Board gesendet. Eine Adresse von 0x30 bis 0x37 teilt der Bibliothek mit, dass es sich um ein Board mit der ATtiny404-Bridge handelt; das dritte Argument wird dann ignoriert.

ReturnsDas Sensorobjekt.

Parameter

TypNameBeschreibung
sensorType_tDie Einstellungen für das Frontend und die Wandlung, etwa SENSOR_CO. Die Voreinstellungen befinden sich in der Datei src/sensorConfigData.h der Bibliothek.
uint8_t_adcAddrDie Adresse des Boards. Verwenden Sie für dieses Board 0x30 bis 0x37, passend zum ADDRESS-Schalter. Bei jeder anderen Adresse, etwa der Standardadresse DEFAULT_ADC_ADDR (0x49), spricht begin() den ADS1115 direkt unter dieser Adresse an statt über die Bridge.
int_configPinGPIO für LMPEN beim direkt verdrahteten Board. Bei diesem Board ungenutzt.
sensor.begin()returns bool

Startet I2C mit Wire.begin(), prüft, ob die Bridge antwortet, sendet ihr die ADC-Verstärkung und die langsamste ADC-Datenrate und anschließend die LMP91000-Einstellungen aus der Sensorkonfiguration. Jeder Befehl an die Bridge wartet bis zu 500 ms auf eine Antwort.

Returnstrue, wenn jeder Schritt erfolgreich war, false, wenn die Bridge nicht geantwortet oder einen Fehler gemeldet hat.

sensor.getPPM()returns double

Fordert von der Bridge eine ADC-Wandlung an und rechnet die Spannung in eine Konzentration um: Sie zieht den internen Nullpunkt ab (ein Anteil der 2,5-V-Referenz des Boards), addiert die Nullpunktkalibrierung der Konfiguration, teilt durch die TIA-Verstärkung, um den Zellenstrom zu erhalten, und teilt dann durch die Nanoampere pro PPM der Konfiguration. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Konzentration in PPM, berechnet mit der Sensorkonfiguration, die Sie dem Konstruktor übergeben haben.

sensor.getPPB()returns double

Die im Beispiel auskommentierte Alternative: derselbe Messwert wie bei getPPM(), multipliziert mit 1000.

ReturnsDie Konzentration in PPB.

Zusammenfassung​

SENSOR_CO ist die Voreinstellung für eine SGX-4CO-Kohlenmonoxidzelle. Für die SGX-4OX-ROHS-Sauerstoffzelle dieses Boards gibt es in den Bibliotheken noch keine Voreinstellung, daher wird der vom Beispiel ausgegebene Wert mit den Einstellungen der CO-Zelle berechnet. Bias und Verstärkung des Frontends stellen Sie selbst ein:

  • Kopieren Sie eine der Voreinstellungen aus src/sensorConfigData.h als Ihren eigenen sensorType in Ihren Sketch und übergeben Sie ihn mit der Adresse 0x30 an den Konstruktor.
  • Die Zelle benötigt eine Bias-Spannung von −600 mV. Mit der 2,5-V-Referenz des Boards ist das BIAS_SIGN_NEGATIVE mit BIAS_24_PERCENT (24 % von 2,5 V sind 0,6 V).
  • Behalten Sie REF_EXTERNAL bei: Das Board hat eine externe 2,5-V-Referenz.
  • Der Ausgangsstrom der Zelle in Luft beträgt 0,1 ± 0,03 mA, und ihr Ausgang ist logarithmisch, S = K ln(1/(1-C)), sodass die lineare PPM-Berechnung der Bibliothek ihn nicht direkt in % vol umrechnet.

Nach dem Einschalten kann die Zelle bis zu 15 Minuten brauchen, bis sie sich eingependelt hat. Lassen Sie sie daher laufen, bevor Sie einem Messwert trauen.

Bis zu acht Boards teilen sich einen Bus: Geben Sie jedem mit dem ADDRESS-Schalter eine eigene Adresse und erstellen Sie pro Adresse ein ElectrochemicalGasSensor, von 0x30 bis 0x37.