Zum Hauptinhalt springen

Single sensor

Was dieses Beispiel zeigt​

Das Beispiel singleSensor erzeugt ein Sensorobjekt mit der Konfiguration SENSOR_CO, startet es und gibt alle 2,5 Sekunden einen Messwert in PPM aus. Es übergibt keine Adresse, daher verwendet der Konstruktor seinen Standardwert DEFAULT_ADC_ADDR (0x49).

Sie müssen LMPEN bei diesem Board nicht anschließen, was auch immer die Kommentare im Sketch sagen: Das Board hält den Pin selbst auf Low.

Der Beispielcode​

Select Board
singleSensor.ino
/**
**************************************************
*
* @file singleSensor.ino
* @brief See how to init one sensor and make a simple reading of PPM of gas.
*
* To successfully run the sketch:
* - Connect LMPEN pin to GND or a GPIO pin so the breakout can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Configurations for each of the sensor types are in sensorConfigData.h in the library's 'src' folder
// Create the sensor object with the according type
ElectrochemicalGasSensor sensor(SENSOR_CO);

// If you are using a custom I2C address (for multiple sensors) use:
// ElectrochemicalGasSensor sensor(SENSOR_SO2, 0x4B, 5);
// For more details on this, see customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Was dieses Board mit dem Sketch in der vorliegenden Form ausgibt, wurde noch nicht gemessen. Beim Test dieses Boards über Qwiic fand ein I2C-Scan nur eine Adresse, 0x30, und mit der MicroPython-Bibliothek schlug begin() für einen Sensor fehl, der mit 0x49 erzeugt wurde, der von diesem Sketch verwendeten Standardadresse. Schlägt begin() fehl, gibt der Sketch ERROR: Can't init the sensor! Check connections! aus und hält an.

Ist begin() erfolgreich, gibt der Sketch Folgendes aus:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Danach folgt alle 2,5 Sekunden eine Zeile Sensor reading: mit einem Wert mit fünf Dezimalstellen und PPM.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Erzeugt das Sensorobjekt mit einer Sensorkonfiguration, einer Adresse und einem LMPEN-Pin. Es wird nichts gesendet, bis Sie begin() aufrufen. begin() wählt anhand der Adresse, wie mit dem Board kommuniziert wird: Bei 0x30 bis 0x37 werden die Befehle der ATtiny404-Bridge verwendet und das dritte Argument ignoriert; jede andere Adresse gilt als eigene Adresse des ADS1115, und der LMP91000 wird direkt beschrieben.

ReturnsDas Sensorobjekt.

Parameter

TypNameBeschreibung
sensorType_tDie Einstellungen für Eingangsstufe und Wandlung, im Beispiel SENSOR_CO. Die Voreinstellungen befinden sich in der Datei src/sensorConfigData.h der Bibliothek.
uint8_t_adcAddrDie Adresse, DEFAULT_ADC_ADDR (0x49), wenn sie weggelassen wird, wie im Beispiel.
int_configPinDer GPIO-Pin, der mit LMPEN verbunden ist, -1 (keiner), wenn er weggelassen wird. Wird bei einer Adresse von 0x30 bis 0x37 nicht verwendet.
sensor.begin()returns bool

Startet I2C mit Wire.begin(). Bei einer Adresse von 0x30 bis 0x37 prüft es, ob die Bridge antwortet, sendet ihr die ADC-Verstärkung und die langsamste ADC-Datenrate und anschließend die LMP91000-Einstellungen; jeder Bridge-Befehl wartet bis zu 500 ms. Bei jeder anderen Adresse startet es den ADS1115 unter dieser Adresse mit derselben Verstärkung und Datenrate, setzt den LMPEN-Pin auf High, falls einer angegeben wurde, und schreibt dann die LMP91000-Einstellungen, wobei es diesen Pin währenddessen auf Low hält.

Returnstrue, wenn jeder Schritt erfolgreich war, andernfalls false.

sensor.getPPM()returns double

Führt eine ADC-Messung durch und wandelt die Spannung in eine Konzentration um: Es subtrahiert die interne Nullstelle (einen Anteil der 2,5-V-Referenz), addiert die Nullpunktkalibrierung der Konfiguration, teilt durch die TIA-Verstärkung, um den Zellenstrom zu erhalten, und teilt dann durch die Nanoampere pro PPM der Konfiguration. Ein negatives Ergebnis wird als 0 zurückgegeben.

ReturnsDie Konzentration in PPM, berechnet mit der Sensorkonfiguration, die Sie dem Konstruktor übergeben haben.

sensor.getPPB()returns double

Die im Beispiel auskommentierte Alternative: derselbe Messwert wie bei getPPM(), multipliziert mit 1000.

ReturnsDie Konzentration in PPB.

Zusammenfassung​

SENSOR_CO ist die Voreinstellung für eine SGX-4CO-Kohlenmonoxidzelle. Die Bibliothek hat noch keine Voreinstellung für die SGX-4OX-ROHS-Sauerstoffzelle dieses Boards, daher wird der Wert, den das Beispiel ausgibt, mit den Einstellungen der CO-Zelle berechnet. Die Seite Benutzerdefinierte Konfiguration zeigt, wie Sie Ihre eigene schreiben.