Zum Hauptinhalt springen

Benutzerdefinierte Konfiguration

Was dieses Beispiel zeigt​

Das Beispiel customConfig der Bibliothek baut sein eigenes sensorType-Preset auf: die Empfindlichkeit der Zelle, einen Nullpunkt-Offset, den ADC-Bereich und die Einstellungen des LMP91000 (Verstärkung, Lastwiderstand, Referenz, interner Nullpunkt, Bias, Betriebsmodus). begin() sendet diese Einstellungen an das Board.

Die Werte des Beispiels gehören zu einer anderen Zelle, nicht zur SO2-Zelle dieses Boards: Es verwendet 100 nA/ppm und BIAS_SIGN_NEGATIVE, während die SO2-Zelle 400 nA/ppm und BIAS_SIGN_POSITIVE benötigt. Ersetzen Sie sie durch die unten genannten Werte von SENSOR_SO2, bevor Sie das Beispiel für SO2 verwenden. Bleiben sie wie geschrieben, verfälscht allein die Empfindlichkeit jeden ppm-Wert um den Faktor vier. Das Preset SENSOR_SO2 der Bibliothek verwendet 400 nA/ppm, ADS_GAIN_4_096V, TIA_GAIN_120_KOHM, RLOAD_10_OHM, REF_EXTERNAL, INTERNAL_ZERO_20_PERCENT, BIAS_SIGN_POSITIVE, BIAS_0_PERCENT, FET_SHORT_DISABLED und OP_MODE_3LEAD_AMP_CELL, mit einer Nullpunktkalibrierung von 0.

Auf diesem Board sitzen der LMP91000 und der ADS1115 am eigenen Bus 2 des Boards, und Ihr Controller erreicht sie über die Adresse des Boards am Qwiic-Bus: 0x30 im Auslieferungszustand, 0x30 bis 0x37 mit dem ADDRESS-Schalter. Das Beispiel übergibt keine Adresse, daher verwendet es den Standardwert der Bibliothek, 0x49, der direkt einen ADS1115 anspricht. Übergeben Sie die Adresse des Boards als zweites Argument des Konstruktors, zum Beispiel ElectrochemicalGasSensor sensor(SENSOR_CUSTOM, 0x30);. Wo der Header sagt, LMPEN solle mit einem beliebigen GPIO-Pin verbunden werden: Auf diesem Board ist LMPEN bereits über einen 10-kΩ-Widerstand auf GND gezogen und führt außerdem zum Mikrocontroller auf dem Board, und bei den Adressen des Boards ignoriert die Bibliothek das Enable-Pin-Argument (siehe Hardware-Details).

Das Listing ist die Datei der Bibliothek im angegebenen Commit, abgesehen von einigen reinen Kommentarzeilen im Header, die den Connector mit einem älteren Namen bezeichnen oder auf andere Soldered-Produkte verweisen und weggelassen wurden.

Der Beispielcode​

Select Board
customConfig.ino
/**
**************************************************
*
* @file customConfig.ino
* @brief Create a custom config for the LMP91000 and upload it to the device.
* This enables you to use this breakout with any electrochemical sensor.
*
* To successfully run the sketch:
* - Edit the custom configuration
* - Connect LMPEN to any GPIO pin
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

/**
* Here are parameters to configure for the custom sensor:
*
* nanoAmperesPerPPM: From the datasheet of the particular electrochemical
* sensor, used in the calculation of PPM/PPB
*
* internalZeroCalibration: A fixed value which is summed to the voltage
* measured by the ADS. The value here should make the reading be
* just barely 0 PPM when the sensor is in a place with none of the target gas
*
* adsGain: The gain of the ADS
* The voltage here represents the max range which it can measure
* ADS_GAIN_6_144V 6.144 V
* ADS_GAIN_4_096V 4.096 V
* ADS_GAIN_2_048V 2.048 V
* ADS_GAIN_1_024V 1.024 V
* ADS_GAIN_0_512V 0.512 V
* ADS_GAIN_0_256V 0.256 V
*
* TIA_GAIN_IN_KOHMS: The gain of the amplifier
* This increases the sensitivity of the measurement
* TIA_GAIN_EXTERNAL External resistance
* TIA_GAIN_2_75_KOHM 2.75 kOhm
* TIA_GAIN_3_5_KOHM 3.5 kOhm
* TIA_GAIN_7_KOHM 7 kOhm
* TIA_GAIN_14_KOHM 14 kOhm
* TIA_GAIN_35_KOHM 35 kOhm
* TIA_GAIN_120_KOHM 120 kOhm
* TIA_GAIN_350_KOHM 350 kOhm
*
* RLOAD: The load resistor in the LMP91000
* Specified in the electrochemical sensor's datasheet
* RLOAD_10_OHM 10 Ohm
* RLOAD_33_OHM 33 Ohm
* RLOAD_50_OHM 50 Ohm
* RLOAD_100_OHM 100 Ohm
*
* REF_SOURCE: Source of the control voltage reference
* For our breakout, use external, there's a 2.5V external
* reference voltage
* REF_INTERNAL Internal
* REF_EXTERNAL External
*
* INTERNAL_ZERO: Internal zero selection
* If the electrochemical sensor has a positive polarity, you
* would usually want to use 20% for the most headroom in the signal
* INTERNAL_ZERO_20_PERCENT 20%
* INTERNAL_ZERO_50_PERCENT 50%
* INTERNAL_ZERO_67_PERCENT 67%
* INTERNAL_ZERO_BYPASSED Internal zero bypassed
*
* BIAS_SIGN: The polarity of the bias voltage
* BIAS_SIGN_NEGATIVE Negative
* BIAS_SIGN_POSITIVE Positive
*
* BIAS: Added bias, percentage of the reference voltage
* Most sensors don't require this, check each sensor's datasheet
* BIAS_0_PERCENT 0%
* BIAS_1_PERCENT 1%
* BIAS_2_PERCENT 2%
* BIAS_4_PERCENT 4%
* BIAS_6_PERCENT 6%
* ...
* BIAS_22_PERCENT 22%
* BIAS_24_PERCENT 24%
*
* FET_SHORT: Short the FET
* Used to perserve the electrochemical sensor
* Has to be disabled for the sensor to be operable
* FET_SHORT_DISABLED Disabled
* FET_SHORT_ENABLED Enabled
*
* OP_MODE: Mode of operation
* OP_MODE_DEEP_SLEEP Deep Sleep (default)
* OP_MODE_2LEAD_GROUND_CELL 2-lead ground referred galvanic cell
* OP_MODE_STANDBY Standby
* OP_MODE_3LEAD_AMP_CELL 3-lead amperometric cell
* OP_MODE_TEMPERATURE_TIA_OFF Temperature measurement (TIA Off)
* OP_MODE_TEMPERATURE_TIA_ON Temperature measurement (TIA On)
*
* For more details, check thge LMP91000 datasheet, chapter 7.6
*/

// Here is an example of a custom configuration:
const sensorType SENSOR_CUSTOM = {
100.0F, // nanoAmperesPerPPM
0, // internalZeroCalibration
ADS_GAIN_4_096V, // adsGain
TIA_GAIN_120_KOHM, // TIA_GAIN_IN_KOHMS
RLOAD_10_OHM, // RLOAD
REF_EXTERNAL, // REF_SOURCE
INTERNAL_ZERO_20_PERCENT, // INTERNAL_ZERO
BIAS_SIGN_NEGATIVE, // BIAS_SIGN
BIAS_0_PERCENT, // BIAS
FET_SHORT_DISABLED, // FET_SHORT
OP_MODE_3LEAD_AMP_CELL, // OP_MODE
};

// Create the sensor object with the custom type
ElectrochemicalGasSensor sensor(SENSOR_CUSTOM);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// Print the reading with 5 digits of precision
Serial.println("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Danach gibt der Sketch alle 2,5 Sekunden Sensor reading: aus, mit dem Wert in ppm in der Zeile darunter.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erstellt das Sensorobjekt aus einem Preset, hier dem sketcheigenen SENSOR_CUSTOM, einer Adresse und einem optionalen Enable-Pin. Das Beispiel übergibt nur das Preset, daher ist die Adresse der Standardwert 0x49.

ReturnsKonstruktor.

Parameter

ParameterTypBeschreibung
_tsensorTypeDas Preset: Empfindlichkeit in nA/ppm, Nullpunktkalibrierung in Volt, ADC-Verstärkung, dann die LMP91000-Einstellungen in der Reihenfolge, in der der Sketch sie auflistet.
_adcAddruint8_tDie Adresse, an der die Bibliothek kommuniziert. 0x30 bis 0x37 ist der Bridge-Bereich, eingestellt über den ADDRESS-Schalter des Boards; jeder andere Wert spricht einen ADS1115 direkt an dieser Adresse an. Standard 0x49.
_configPinintGPIO für die Enable-Leitung des Frontends. Wird bei den Adressen 0x30 bis 0x37 ignoriert. Standard -1.
bool begin()returns bool

Startet I2C, prüft, ob das Board antwortet, und sendet die ADC-Verstärkung und die aus dem Preset erzeugten LMP91000-Registerwerte an das Board.

Returnstrue, wenn das Board geantwortet und jede Einstellung übernommen hat, sonst false.

double getPPM()returns double

Lässt das Board eine ADC-Messung durchführen und rechnet sie mit der Verstärkung und der Empfindlichkeit des Presets in eine Gaskonzentration um. Ein Ergebnis unter null wird als 0 zurückgegeben.

ReturnsGaskonzentration in ppm.

Zusammenfassung​

Die Empfindlichkeit im Preset skaliert jedes Ergebnis, daher liefert ein falscher Wert einen falschen ppm-Wert, selbst wenn die Hardware funktioniert. Die Verstärkung des Frontends muss einer der festen TIA_GAIN_*-Werte sein, damit die Berechnung funktioniert: TIA_GAIN_EXTERNAL erfordert zusätzlich setCustomTiaGain().