Zum Hauptinhalt springen

SO2-Konzentration auslesen

Was dieses Beispiel zeigt​

Das Beispiel bridgeBoard der Bibliothek startet den Breakout an der I2C-Adresse 0x30 und gibt die Gaskonzentration in ppm alle 2,5 Sekunden aus. Es ist derselbe Sketch, den auch der Schnellstart verwendet.

Das Beispiel erstellt den Sensor mit dem Preset für die CO-Zelle, SENSOR_CO. SENSOR_SO2 ist das Preset der Bibliothek für die SGX-4SO2-Zelle auf diesem Board: Ändern Sie in der Zeile, die sensor erstellt, SENSOR_CO in SENSOR_SO2, um SO2-Werte zu erhalten.

Das Listing ist die Datei der Bibliothek im festgelegten Commit, bis auf einige reine Kommentarzeilen, die den Connector mit einem älteren Namen bezeichnen oder auf andere Soldered-Produkte verweisen und weggelassen wurden. Wo die Kommentare sagen, die Adresse werde mit Jumpern eingestellt, wird sie auf diesem Board mit dem ADDRESS-Schalter eingestellt (0x30 im Auslieferungszustand), und die Adress-Jumper JP2 bis JP4 bleiben im Auslieferungszustand. Wo sie sagen, LMPEN sei fest mit GND verbunden, wird LMPEN auf diesem Board durch einen 10-kΩ-Widerstand auf GND gezogen und führt zusätzlich zum Mikrocontroller auf dem Board (siehe Hardware-Details).

Der Beispielcode​

Select Board
bridgeBoard.ino
/**
**************************************************
*
* @file bridgeBoard.ino
* @brief See how to init a sensor on the new ATtiny404 bridge board revision,
*
* To successfully run the sketch:
* - Set the desired address using the jumpers on the back of the board
* (address = 0x30 + jumper offset, giving a range of 0x30-0x37)
* - Run the sketch and open serial monitor at 115200 baud!
*
* Note: on this board revision, LMPEN is hardwired to GND, so there's
* no configPin argument to pass - the constructor's third argument
* is ignored whenever the address falls in the bridge range (0x30-0x37).
*
*
* @authors @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Any additional boards on the same bus just need a different jumper setting
// (0x30-0x37), same as twoSensors.ino does for legacy boards with 0x49/0x4A/0x4B.
ElectrochemicalGasSensor sensor(SENSOR_CO, 0x30);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections and jumper address!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Nach dieser Zeile folgt alle 2,5 Sekunden eine neue Zeile Sensor reading: mit der Konzentration in ppm auf fünf Nachkommastellen.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erstellt das Sensorobjekt. Der Sensortyp ist ein Preset mit der Empfindlichkeit der Zelle sowie den Einstellungen des Frontends und des ADC. Die Adresse legt fest, wie die Bibliothek mit dem Board kommuniziert: 0x30 bis 0x37 ist der Bridge-Bereich.

ReturnsKonstruktor.

Parameter

ParameterTypBeschreibung
_tsensorTypeDas Zellen-Preset. SENSOR_SO2 ist das Preset für die Zelle dieses Boards.
_adcAddruint8_tDie Adresse, über die die Bibliothek kommuniziert. 0x30 bis 0x37 ist der Bridge-Bereich, der mit dem ADDRESS-Schalter des Boards eingestellt wird; jeder andere Wert spricht einen ADS1115 direkt an dieser Adresse an. Standard 0x49. Das Beispiel übergibt 0x30.
_configPinintGPIO für die Enable-Leitung des Frontends. Wird bei den Adressen 0x30 bis 0x37 ignoriert. Standard -1.
bool begin()returns bool

Startet I2C, prüft, ob das Board antwortet, und sendet die ADC- und LMP91000-Einstellungen aus dem Preset an das Board. Rufen Sie sie einmal vor jeder Messung auf.

Returnstrue, wenn das Board geantwortet und jede Einstellung übernommen hat, sonst false.

double getPPM()returns double

Lässt das Board eine ADC-Messung durchführen und rechnet sie in eine Gaskonzentration um, unter Verwendung der 2,5-V-Referenz, der Verstärkung des Frontends und der Empfindlichkeit der Zelle aus dem Preset. Ein Ergebnis unter null wird als 0 zurückgegeben.

ReturnsGaskonzentration in ppm.

double getPPB()returns double

Dieselbe Messung wie getPPM(), in Parts per Billion. Das Beispiel zeigt sie als Alternative in einem Kommentar.

ReturnsGaskonzentration in ppb (getPPM() x 1000).

Zusammenfassung​

begin() sendet die Einstellungen der Zelle einmal, danach fordert jeder Aufruf von getPPM() vom Board eine neue Wandlung an. Die Adresse im Konstruktor muss der Einstellung des ADDRESS-Schalters entsprechen, und jedes Board am selben Bus braucht eine eigene Adresse.