Zum Hauptinhalt springen

Einzelner Sensor

Was dieses Beispiel zeigt​

Das Beispiel singleSensor der Bibliothek erstellt ein Sensorobjekt, startet es und gibt alle 2,5 Sekunden die Gaskonzentration in ppm aus.

Das Beispiel erstellt den Sensor mit dem Zellen-Preset für CO, SENSOR_CO. SENSOR_SO2 ist das Preset der Bibliothek für die SGX-4SO2-Zelle auf diesem Board: Ändern Sie SENSOR_CO in der Zeile, die sensor erstellt, in SENSOR_SO2, um SO2-Werte zu erhalten.

Auf diesem Board sitzen der LMP91000 und der ADS1115 am eigenen Bus 2 des Boards, und Ihr Controller erreicht sie über die Adresse des Boards am Qwiic-Bus: 0x30 im Auslieferungszustand, 0x30 bis 0x37 mit dem ADDRESS-Schalter. Das Beispiel übergibt keine Adresse und verwendet daher den Standardwert der Bibliothek, 0x49, der direkt einen ADS1115 anspricht. Übergeben Sie die Adresse des Boards als zweites Argument des Konstruktors, zum Beispiel ElectrochemicalGasSensor sensor(SENSOR_SO2, 0x30);. Wo im Header steht, dass LMPEN mit GND oder einem GPIO-Pin verbunden werden soll, ist LMPEN auf diesem Board bereits durch einen 10-kΩ-Widerstand auf GND gezogen und führt zusätzlich zum Mikrocontroller auf dem Board. Bei den Adressen des Boards ignoriert die Bibliothek das Enable-Pin-Argument (siehe Hardware-Details).

Das Listing ist die Datei der Bibliothek im festgelegten Commit, abgesehen von einigen Zeilen nur mit Kommentaren im Header, die den Connector mit einem älteren Namen benennen oder auf andere Soldered-Produkte verweisen und weggelassen wurden.

Der Beispielcode​

Select Board
singleSensor.ino
/**
**************************************************
*
* @file singleSensor.ino
* @brief See how to init one sensor and make a simple reading of PPM of gas.
*
* To successfully run the sketch:
* - Connect LMPEN pin to GND or a GPIO pin so the breakout can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Configurations for each of the sensor types are in sensorConfigData.h in the library's 'src' folder
// Create the sensor object with the according type
ElectrochemicalGasSensor sensor(SENSOR_CO);

// If you are using a custom I2C address (for multiple sensors) use:
// ElectrochemicalGasSensor sensor(SENSOR_SO2, 0x4B, 5);
// For more details on this, see customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Nach dieser Zeile folgt alle 2,5 Sekunden eine neue Zeile Sensor reading: mit der Konzentration in ppm auf fünf Dezimalstellen.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erstellt das Sensorobjekt aus einem Zellen-Preset, einer Adresse und einem optionalen Enable-Pin. Das Beispiel übergibt nur das Preset, daher ist die Adresse der Standardwert 0x49.

ReturnsKonstruktor.

Parameter

ParameterTypBeschreibung
_tsensorTypeDas Zellen-Preset. SENSOR_SO2 ist das Preset für die Zelle dieses Boards.
_adcAddruint8_tDie Adresse, mit der die Bibliothek kommuniziert. 0x30 bis 0x37 ist der Bridge-Bereich, der über den ADDRESS-Schalter des Boards eingestellt wird; jeder andere Wert spricht einen ADS1115 direkt unter dieser Adresse an. Standardwert 0x49.
_configPinintGPIO für die Enable-Leitung des Frontends. Wird bei den Adressen 0x30 bis 0x37 ignoriert. Standardwert -1.
bool begin()returns bool

Startet I2C, prüft, ob das Board antwortet, und sendet die ADC- und LMP91000-Einstellungen aus dem Preset an das Board. Rufen Sie sie einmal vor jeder Messung auf.

Returnstrue, wenn das Board geantwortet und alle Einstellungen übernommen hat, sonst false.

double getPPM()returns double

Lässt das Board eine ADC-Messung durchführen und rechnet sie in eine Gaskonzentration um, unter Verwendung der 2,5-V-Referenz, der Verstärkung des Frontends und der Empfindlichkeit der Zelle aus dem Preset. Ein Ergebnis unter null wird als 0 zurückgegeben.

ReturnsGaskonzentration in ppm.

double getPPB()returns double

Dieselbe Messung wie getPPM(), in Teilen pro Milliarde. Das Beispiel zeigt sie als Alternative in einem Kommentar.

ReturnsGaskonzentration in ppb (getPPM() x 1000).

Zusammenfassung​

begin() sendet die Einstellungen der Zelle einmalig, danach fordert jeder Aufruf von getPPM() vom Board eine neue Wandlung an. Um stattdessen ppb auszugeben, tauschen Sie die beiden Zeilen double reading = und ändern " PPM" in " PPB", damit die Bezeichnung zum Wert passt.