Zum Hauptinhalt springen

Two sensors

Was dieses Beispiel zeigt​

Das Beispiel twoSensors der Bibliothek liest zwei Boards an einem I2C-Bus aus. Es erzeugt sensorCO mit der CO-Zellen-Voreinstellung an der Adresse 0x4A mit GPIO 25 als Enable-Pin und sensorNO2 mit der NO2-Zellen-Voreinstellung an der Adresse 0x49 mit GPIO 32. Alle 2,5 Sekunden gibt es den ersten Messwert in ppm und den zweiten in ppb aus.

SENSOR_SO2 ist die Voreinstellung der Bibliothek für die SGX-4SO2-Zelle auf diesem Board: Setzen Sie sie anstelle der Voreinstellung bei jedem Sensor ein, der eines dieser Boards ist. Den Adressschalter und die Jumper dieses Boards beschreibt Hardware-Details.

Auf diesem Board sitzen der LMP91000 und der ADS1115 am eigenen Bus 2 des Boards. Ihr Controller erreicht sie über die Adresse des Boards am Qwiic-Bus, 0x30 bis 0x37 mit dem ADDRESS-Schalter (0x30 im Auslieferungszustand). Die Adressen 0x4A und 0x49 des Beispiels sprechen direkt einen ADS1115 an. Geben Sie bei zwei dieser Boards jedem eine eigene Adresse am ADDRESS-Schalter und übergeben Sie diese Adresse als zweites Argument des Konstruktors. Wo der Header angibt, die LMPEN-Pins mit einem GPIO-Pin zu verbinden: Auf diesem Board ist LMPEN bereits über einen 10-kΩ-Widerstand auf GND gezogen und führt zusätzlich zum Mikrocontroller auf dem Board. Bei den Adressen des Boards ignoriert die Bibliothek das Enable-Pin-Argument, hier GPIO 25 und GPIO 32.

Der Kommentar im Header „Set different addresses using the jumpers on the back of the breakout" beschreibt nicht das Vorgehen für dieses Board. Lassen Sie die Adress-Jumper JP2 bis JP4 im Auslieferungszustand: Wenn Sie JP3 oder JP4 verändern, liefert das Board möglicherweise keine Messwerte mehr, und werden zwei davon geschlossen, entsteht je nach Paar ein Kurzschluss von 3V3 mit SDA2, von 3V3 mit SCL2 oder von SDA2 mit SCL2. Siehe Hardware-Details.

Das Listing ist die Datei der Bibliothek im festgelegten Commit, abgesehen von einigen reinen Kommentarzeilen im Header, die den Connector unter einem älteren Namen nennen oder auf andere Soldered-Produkte verweisen und weggelassen wurden.

Der Beispielcode​

Select Board
twoSensors.ino
/**
**************************************************
*
* @file twoSensors.ino
* @brief See how to init two sensors and make two readings of PPM of gas.
*
* To successfully run the sketch:
* - Set different addresses using the jumpers on the back of the breakout
* - Connect LMPEN pins to a GPIO pin so the breakouts can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Create two different sensor objects
ElectrochemicalGasSensor sensorCO(SENSOR_CO, 0x4A, 25);
ElectrochemicalGasSensor sensorNO2(SENSOR_NO2, 0x49, 32);
// To see how the custom addresses are determined, check customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init breakout #1
if (!sensorCO.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("CO sensor initialized successfully!");

// Init breakout #2
if (!sensorNO2.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("NO2 sensor initialized successfully!");
}

void loop()
{
// Make the reading of CO and print it
double COreading = sensorCO.getPPM();

// Print the reading with 5 digits of precision
Serial.print("CO sensor reading: ");
Serial.print(COreading, 5);
Serial.println(" PPM");

// Make the reading of NO2 and print it
double NO2reading = sensorNO2.getPPB();

// Print the reading with 5 digits of precision
Serial.print("NO2 sensor reading: ");
Serial.print(NO2reading, 5);
Serial.println(" PPB");

// Wait a bit before reading again
delay(2500);
}

Erwartetes Ergebnis:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
CO sensor initialized successfully!
NO2 sensor initialized successfully!

Nach diesen Zeilen folgen alle 2,5 Sekunden eine Zeile CO sensor reading: in ppm und eine Zeile NO2 sensor reading: in ppb, jeweils mit fünf Nachkommastellen. Startet ein Board nicht, gibt der Sketch ERROR: Can't init the sensor! Check connections! aus und bleibt dort stehen.

Verwendete Funktionen​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Erzeugt ein Sensorobjekt aus einer Zellen-Voreinstellung, einer Adresse und einem optionalen Enable-Pin. Das Beispiel erzeugt zwei, eines pro Board.

ReturnsKonstruktor.

Parameter

ParameterTypBeschreibung
_tsensorTypeDie Voreinstellung der Zelle. SENSOR_SO2 ist die Voreinstellung für die Zelle dieses Boards.
_adcAddruint8_tDie Adresse, mit der die Bibliothek kommuniziert. 0x30 bis 0x37 ist der Bridge-Bereich, eingestellt über den ADDRESS-Schalter des Boards; jeder andere Wert spricht direkt einen ADS1115 an dieser Adresse an. Standard 0x49.
_configPinintGPIO für die Enable-Leitung des Front-Ends. Wird bei den Adressen 0x30 bis 0x37 ignoriert. Standard -1.
bool begin()returns bool

Startet I2C, prüft, ob das Board antwortet, und sendet die ADC- und LMP91000-Einstellungen aus der Voreinstellung an das Board. Das Beispiel ruft sie einmal für jeden Sensor auf.

Returnstrue, wenn das Board geantwortet und alle Einstellungen übernommen hat, sonst false.

double getPPM()returns double

Lässt das Board eine ADC-Messung durchführen und rechnet sie in eine Gaskonzentration um, anhand der 2,5-V-Referenz, der Verstärkung des Front-Ends und der Empfindlichkeit der Zelle aus der Voreinstellung. Ein Ergebnis unter null wird als 0 zurückgegeben.

ReturnsGaskonzentration in ppm.

double getPPB()returns double

Derselbe Messwert wie bei getPPM(), in Parts per Billion. Das Beispiel verwendet sie für den zweiten Sensor.

ReturnsGaskonzentration in ppb (getPPM() x 1000).

Zusammenfassung​

Jedes ElectrochemicalGasSensor-Objekt behält seine eigene Adresse und Voreinstellung. Ein Sketch kann also mehrere Boards am selben Bus auslesen, solange keine zwei dieselbe Adresse haben.