Single readings in forced mode

What this example shows

In FORCED mode the BMP585 takes one measurement when you ask for it, then goes back to sleep. That suits projects that need a reading only now and then. The sketch lowers the oversampling to 1x, bypasses the IIR filter, and then asks for one measurement per second.

Connect the breakout over I2C (3V3, GND, SDA, SCL, or a Qwiic cable). The INT pin is not needed: the sketch reads the sensor's interrupt status over I2C.

The example code

Select Board

forcedModeCustomConfig.ino

#include <BMP585-SOLDERED.h>

// Create an instance of the BMP585 sensor
Soldered_BMP585 pressureSensor;

void setup()
{
    // Initialize serial for output
    Serial.begin(115200);
    Serial.println("BMP585 Example - Forced Mode & Custom Config");

    // Initialize I2C bus
    Wire.begin();

    // Check if sensor is connected and initialize it.
    // Address is optional, defaults to 0x47
    while (pressureSensor.begin() != BMP5_OK)
    {
        Serial.println("Error: BMP585 not connected, check wiring and I2C address!");
        delay(1000);
    }

    Serial.println("BMP585 connected!");

    // Lower the oversampling from the library default since forced mode is
    // typically used for infrequent, quick readings. ODR is ignored in
    // forced mode, but still needs to be set to a valid value
    pressureSensor.setOSRODRConfig(BMP5_OVERSAMPLING_1X, BMP5_OVERSAMPLING_1X, BMP5_ODR_50_HZ);

    // Bypass the IIR filter since forced mode readings aren't continuous
    // enough for the filter to settle
    pressureSensor.setIIRConfig(BMP5_IIR_FILTER_BYPASS, BMP5_IIR_FILTER_BYPASS);

    // Trigger the first measurement
    pressureSensor.setMode(BMP5_POWERMODE_FORCED);
}

void loop()
{
    // Wait for the measurement to be ready
    uint8_t interruptStatus = 0;
    pressureSensor.getInterruptStatus(&interruptStatus);

    if (interruptStatus & BMP5_INT_ASSERTED_DRDY)
    {
        if (pressureSensor.getSensorData() == BMP5_OK)
        {
            Serial.print("Pressure: ");
            Serial.print(pressureSensor.pressure, 2);
            Serial.print(" Pa\t");
            Serial.print("Temperature: ");
            Serial.print(pressureSensor.temperature, 2);
            Serial.println(" degC");
        }

        // Trigger the next measurement
        pressureSensor.setMode(BMP5_POWERMODE_FORCED);

        // Only take a reading once per second
        delay(1000);
    }
}

Expected result:

Serial MonitorAutoscrollShow timestampNewline115200 baud

Message (Enter to send message to the board)

BMP585 Example - Forced Mode & Custom Config
BMP585 connected!
Pressure: 101308.61 Pa	Temperature: 23.44 degC
Pressure: 101318.58 Pa	Temperature: 23.46 degC
Pressure: 101320.98 Pa	Temperature: 23.44 degC

One line arrives about every second: the pressure in pascals and the temperature in °C, each with two decimals.

Functions used

Soldered_BMP585()returns Soldered_BMP585

Creates the sensor object. Nothing is sent to the sensor until you call begin().

ReturnsThe sensor object.

Wire.begin()returns void

Starts the Arduino Wire (I2C) library and joins the I2C bus as a controller. Call it once, before begin(). Wire comes with the Arduino core and is not part of the BMP585 library.

ReturnsNothing.

pressureSensor.begin(uint8_t address = BMP5_I2C_ADDR_SEC, TwoWire &wirePort = Wire)returns int8_t

Starts the sensor over I2C: a soft reset, a check that the BMP585 is there, then temperature oversampling 64x, pressure oversampling 4x, a 50 Hz output data rate with pressure enabled, and NORMAL power mode. The library supports I2C only.