Skip to main content

Brzi početak

Povežite skener s mikrokontrolerom preko UART-a, instalirajte biblioteku i ispišite svaki barkod koji skenirate.

Programirate kontroler spojen na ovu pločicu. Sama pločica se ne programira.

Najprije prebacite skener na UART. Skener se isporučuje u USB načinu rada i u tom načinu ne odgovara na RX i TX. Jednom skenirajte konfiguracijski barkod POR232 (TTL/RS232) kako biste ga prebacili na UART. U repozitoriju Arduino biblioteke u mapi barcodes nalazi se datoteka naziva TTL-Mode.PNG.

Pinovi headera rade s logikom od 3,3 V. Kada pločicu napajate preko headera kontrolera umjesto preko USB-C, koristite 3,3 V pin kontrolera i nikada ne spajajte 3V3 na 5 V.

1. Povežite pločicu​

Ovaj je primjer napisan za ESP32 pločicu: sa skenerom komunicira preko hardverskog UART2 (HardwareSerial(2)) ESP32-a na GPIO4 i GPIO5. Podatkovne linije spojite unakrižno: TX kontrolera ide na RX skenera, a TX skenera ide na RX kontrolera.

KontrolerSoldered Barcode Scanner DE2120
GPIO5 (TX)RX
GPIO4 (RX)TX
3V33V3
GNDGND
Pločica Soldered Barcode Scanner DE2120 gledana odozgo
Pogled odozgo

2. Instalirajte biblioteku​

Instalirajte Soldered DE2120 iz njezina GitHub repozitorija.

🔗Soldered DE2120 Arduino biblioteka

Provjerena Arduino biblioteka na commitu 697eb25

→

Savjet: preuzimanje s GitHuba. Na GitHub stranici biblioteke kliknite zeleni gumb Code i odaberite Download ZIP, zatim je dodajte u Arduino IDE preko Sketch → Include Library → Add .ZIP Library....

Biblioteka uključuje SoftwareSerial.h, pa mora biti instalirana biblioteka SoftwareSerial čak i kada vaša skica koristi hardverski UART. Primjeri biblioteke upućuju na Arduino Library Manager za njezinu instalaciju.

3. Pokrenite prvi primjer​

Otvorite HardwareScan iz primjera biblioteke, odaberite svoju ESP32 pločicu i port te učitajte skicu. Skica pokreće UART2 ESP32-a na GPIO4 (RX) i GPIO5 (TX), pronalazi skener i ispisuje svaki kod koji pročita.

Select Board
HardwareScan.ino
/**
 **************************************************
 *
 * @file        HardwareScan.ino
 * @brief       Scan and output barcodes using the DE2120 1D/2D barcode
 *              scanner module over HardwareSerial (UART2) on ESP32.
 *
 *              Unlike SoftwareSerial, HardwareSerial uses a dedicated
 *              UART peripheral for reliable communication at 115200 bps.
 *              The library will automatically negotiate the baud rate
 *              down to 9600 bps on first connect.
 *
 *              Default wiring: GPIO4 = RX (scanner TX),
 *              GPIO5 = TX (scanner RX). Change the pin arguments in
 *              scannerSerial.begin() to match your wiring.
 *
 *              The scanner must first be put into TTL/RS232 mode by
 *              scanning the POR232 barcode from the DYScan settings
 *              manual before uploading this sketch.
 *
 *              Make sure you have SoftwareSerial library installed. It
 *              can be found in Arduino library manager.
 *
 * @authors     Fran Fodor @ soldered.com
 ***************************************************/

#include "HardwareSerial.h"
HardwareSerial scannerSerial(2); // Use UART2

#include "DE2120-SOLDERED.h"
DE2120_Soldered scanner;

#define BUFFER_LEN 40
char scanBuffer[BUFFER_LEN];

void setup()
{
  Serial.begin(115200);
  Serial.println("DE2120 Scanner Example");

  scannerSerial.begin(115200, SERIAL_8N1, 4, 5); // RX=GPIO4, TX=GPIO5
  delay(500);

  if (scanner.begin(scannerSerial) == false)
  {
    Serial.println("Scanner did not respond. Please check wiring. Did you scan the POR232 barcode? Freezing...");
    while (1);
  }
  Serial.println("Scanner online!");
}

void loop()
{
  if (scanner.readBarcode(scanBuffer, BUFFER_LEN))
  {
    Serial.print("Code found: ");
    for (int i = 0; i < strlen(scanBuffer); i++)
      Serial.print(scanBuffer[i]);
    Serial.println();
  }
  delay(200);
}

4. Provjerite rezultat​

Otvorite Serial Monitor na 115200 baud. Kada skener odgovori, vidjet ćete:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
DE2120 Scanner Example
Scanner online!

Skener se pokreće u ručnom načinu rada, stoga pritisnite tipku okidača na pločici i usmjerite je prema barkodu. Svaki pročitani kod ispisuje se u zasebnom retku kao Code found: iza kojeg slijedi sadržaj koda.

Ako umjesto toga vidite Scanner did not respond. Please check wiring. Did you scan the POR232 barcode? Freezing..., skener je još u USB načinu rada ili su RX i TX zamijenjeni.

5. Ako ne radi​

Nastavite s poglavljem Otklanjanje poteškoća i nakon svake promjene ponovno pokrenite ovaj najjednostavniji primjer.