Skip to main content

Prilagođena konfiguracija senzora

Što prikazuje ovaj primjer​

Primjer customConfig gradi vlastiti sensorType naziva SENSOR_CUSTOM umjesto da koristi neku od gotovih postavki biblioteke, prosljeđuje ga konstruktoru i svake 2,5 sekunde ispisuje koncentraciju plina u ppm. Dugi komentar u skici navodi svako polje i vrijednosti koje ono može imati.

Vrijednosti iz primjera nisu vrijednosti SGX-4CO ćelije za ugljikov monoksid na ovoj pločici. Gotova postavka biblioteke za tu ćeliju je SENSOR_CO, a dva polja se razlikuju:

PoljeU primjeruVrijednost SENSOR_CO
nanoAmperesPerPPM100.0F70.0F
internalZeroCalibration00
adsGainADS_GAIN_4_096VADS_GAIN_4_096V
TIA_GAIN_IN_KOHMSTIA_GAIN_120_KOHMTIA_GAIN_14_KOHM
RLOADRLOAD_10_OHMRLOAD_10_OHM
REF_SOURCEREF_EXTERNALREF_EXTERNAL
INTERNAL_ZEROINTERNAL_ZERO_20_PERCENTINTERNAL_ZERO_20_PERCENT
BIAS_SIGNBIAS_SIGN_NEGATIVEBIAS_SIGN_NEGATIVE
BIASBIAS_0_PERCENTBIAS_0_PERCENT
FET_SHORTFET_SHORT_DISABLEDFET_SHORT_DISABLED
OP_MODEOP_MODE_3LEAD_AMP_CELLOP_MODE_3LEAD_AMP_CELL

Prije prijenosa programa postavite u SENSOR_CUSTOM nanoAmperesPerPPM na 70.0F i TIA_GAIN_IN_KOHMS na TIA_GAIN_14_KOHM, kako bi konfiguracija odgovarala ćeliji na ovoj pločici. Ostala polja već imaju vrijednosti SENSOR_CO.

Što mu je potrebno na ovoj pločici​

Primjer stvara senzor na zadanoj adresi konstruktora, 0x49. Na adresi izvan raspona od 0x30 do 0x37 biblioteka ne koristi most na pločici: begin() pokreće ADS1115 na toj adresi i sam upisuje konfiguraciju LMP91000 preko I2C-a kontrolera. Na ovoj pločici ta dva čipa nalaze se na internoj sabirnici koju gornji header izvodi kao SDA2 i SCL2. Qwiic konektori i SDA1/SCL1 dopiru samo do mosta ATtiny404, a I2C pretraživanje preko Qwiic konektora pronalazi samo most, na adresi 0x30 kakva je isporučena. Primjer ne prosljeđuje nikakav konfiguracijski pin, a LMPEN je na pločici spojen na GND; pogledajte Detalji o hardveru.

Zato za ovaj primjer spojite gornji header, a ne Qwiic kabel: spojite SDA svog kontrolera na SDA2, SCL na SCL2, njegov pin od 3,3 V na 3V3, a GND na GND. Preko Qwiic konektora odgovara samo most.

Adresu mosta, od 0x30 do 0x37, koristi primjer Očitavanje koncentracije CO.

Kôd primjera​

Select Board
customConfig.ino
/**
**************************************************
*
* @file customConfig.ino
* @brief Create a custom config for the LMP91000 and upload it to the device.
* This enables you to use this breakout with any electrochemical sensor.
*
* To successfully run the sketch:
* - Edit the custom configuration
* - Connect LMPEN to any GPIO pin
* - Run the sketch and open serial monitor at 115200 baud!
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

/**
* Here are parameters to configure for the custom sensor:
*
* nanoAmperesPerPPM: From the datasheet of the particular electrochemical
* sensor, used in the calculation of PPM/PPB
*
* internalZeroCalibration: A fixed value which is summed to the voltage
* measured by the ADS. The value here should make the reading be
* just barely 0 PPM when the sensor is in a place with none of the target gas
*
* adsGain: The gain of the ADS
* The voltage here represents the max range which it can measure
* ADS_GAIN_6_144V 6.144 V
* ADS_GAIN_4_096V 4.096 V
* ADS_GAIN_2_048V 2.048 V
* ADS_GAIN_1_024V 1.024 V
* ADS_GAIN_0_512V 0.512 V
* ADS_GAIN_0_256V 0.256 V
*
* TIA_GAIN_IN_KOHMS: The gain of the amplifier
* This increases the sensitivity of the measurement
* TIA_GAIN_EXTERNAL External resistance
* TIA_GAIN_2_75_KOHM 2.75 kOhm
* TIA_GAIN_3_5_KOHM 3.5 kOhm
* TIA_GAIN_7_KOHM 7 kOhm
* TIA_GAIN_14_KOHM 14 kOhm
* TIA_GAIN_35_KOHM 35 kOhm
* TIA_GAIN_120_KOHM 120 kOhm
* TIA_GAIN_350_KOHM 350 kOhm
*
* RLOAD: The load resistor in the LMP91000
* Specified in the electrochemical sensor's datasheet
* RLOAD_10_OHM 10 Ohm
* RLOAD_33_OHM 33 Ohm
* RLOAD_50_OHM 50 Ohm
* RLOAD_100_OHM 100 Ohm
*
* REF_SOURCE: Source of the control voltage reference
* For our breakout, use external, there's a 2.5V external
* reference voltage
* REF_INTERNAL Internal
* REF_EXTERNAL External
*
* INTERNAL_ZERO: Internal zero selection
* If the electrochemical sensor has a positive polarity, you
* would usually want to use 20% for the most headroom in the signal
* INTERNAL_ZERO_20_PERCENT 20%
* INTERNAL_ZERO_50_PERCENT 50%
* INTERNAL_ZERO_67_PERCENT 67%
* INTERNAL_ZERO_BYPASSED Internal zero bypassed
*
* BIAS_SIGN: The polarity of the bias voltage
* BIAS_SIGN_NEGATIVE Negative
* BIAS_SIGN_POSITIVE Positive
*
* BIAS: Added bias, percentage of the reference voltage
* Most sensors don't require this, check each sensor's datasheet
* BIAS_0_PERCENT 0%
* BIAS_1_PERCENT 1%
* BIAS_2_PERCENT 2%
* BIAS_4_PERCENT 4%
* BIAS_6_PERCENT 6%
* ...
* BIAS_22_PERCENT 22%
* BIAS_24_PERCENT 24%
*
* FET_SHORT: Short the FET
* Used to perserve the electrochemical sensor
* Has to be disabled for the sensor to be operable
* FET_SHORT_DISABLED Disabled
* FET_SHORT_ENABLED Enabled
*
* OP_MODE: Mode of operation
* OP_MODE_DEEP_SLEEP Deep Sleep (default)
* OP_MODE_2LEAD_GROUND_CELL 2-lead ground referred galvanic cell
* OP_MODE_STANDBY Standby
* OP_MODE_3LEAD_AMP_CELL 3-lead amperometric cell
* OP_MODE_TEMPERATURE_TIA_OFF Temperature measurement (TIA Off)
* OP_MODE_TEMPERATURE_TIA_ON Temperature measurement (TIA On)
*
* For more details, check thge LMP91000 datasheet, chapter 7.6
*/

// Here is an example of a custom configuration:
const sensorType SENSOR_CUSTOM = {
100.0F, // nanoAmperesPerPPM
0, // internalZeroCalibration
ADS_GAIN_4_096V, // adsGain
TIA_GAIN_120_KOHM, // TIA_GAIN_IN_KOHMS
RLOAD_10_OHM, // RLOAD
REF_EXTERNAL, // REF_SOURCE
INTERNAL_ZERO_20_PERCENT, // INTERNAL_ZERO
BIAS_SIGN_NEGATIVE, // BIAS_SIGN
BIAS_0_PERCENT, // BIAS
FET_SHORT_DISABLED, // FET_SHORT
OP_MODE_3LEAD_AMP_CELL, // OP_MODE
};

// Create the sensor object with the custom type
ElectrochemicalGasSensor sensor(SENSOR_CUSTOM);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// Print the reading with 5 digits of precision
Serial.println("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Retci u nastavku potječu iz pokretanja ovog primjera na ovoj pločici, s kontrolerom spojenim na pinove SDA2, SCL2, 3V3 i GND headera, kako je opisano gore.

Očekivani rezultat u Serijskom monitoru pri 115200 baud:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!
Sensor reading:
0.31747 PPM
Sensor reading:
0.31796 PPM
Sensor reading:
0.30993 PPM
Sensor reading:
0.29262 PPM

Zatim skica svake 2,5 sekunde u zasebnom retku ispisuje Sensor reading: , a nakon toga redak s koncentracijom u ppm na pet decimala i PPM. Rezultat manji od nule ispisuje se kao 0.00000. Ako begin() ne uspije, skica ispisuje ERROR: Can't init the sensor! Check connections! i zaustavlja se.

Korištene funkcije​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Stvara objekt senzora. Primjer prosljeđuje SENSOR_CUSTOM, a adresu i konfiguracijski pin ostavlja na zadanim vrijednostima. Tip sensorType sadrži, redom: nanoAmperesPerPPM, internalZeroCalibration, adsGain, TIA_GAIN_IN_KOHMS, RLOAD, REF_SOURCE, INTERNAL_ZERO, BIAS_SIGN, BIAS, FET_SHORT i OP_MODE.

ReturnsKonstruktor.

Parametri

ParametarTipOpis
_tsensorTypeKonfiguracija ćelije: gotova postavka biblioteke ili vaš vlastiti sensorType. Za SGX-4CO ćeliju na ovoj pločici gotova postavka biblioteke je SENSOR_CO.
_adcAddruint8_tI2C adresa. Zadano DEFAULT_ADC_ADDR, 0x49. Od 0x30 do 0x37 biblioteka komunicira s mostom ATtiny404 na pločici.
_configPinintGPIO koji biblioteka postavlja na nisku razinu dok šalje konfiguraciju ulaznog stupnja, a inače na visoku. Ne koristi se na adresi od 0x30 do 0x37. Zadano -1, nijedan.
bool begin()returns bool

Pokreće I2C pomoću Wire.begin(). Na adresi od 0x30 do 0x37 provjerava odgovara li most, šalje mu pojačanje ADC-a i brzinu podataka iz konfiguracije te postavke ulaznog stupnja, čekajući do 500 ms na svaki odgovor. Na bilo kojoj drugoj adresi pokreće ADC na toj adresi, postavlja njegovo pojačanje i najsporiju brzinu podataka, a zatim upisuje postavke ulaznog stupnja.

Returnstrue ako su svi koraci uspjeli, inače false.

double getPPM()returns double

Izvodi jednu ADC konverziju izlaza ulaznog stupnja, oduzima unutarnju nulu iz konfiguracije, dodaje njezinu kalibraciju nule te pretvara struju ćelije u ppm pomoću njezine osjetljivosti i pojačanja pojačala.

ReturnsKoncentracija plina u ppm. Negativan rezultat vraća se kao 0.

Sve zajedno​

Popunite sensorType vrijednostima svoje ćelije (za ovu pločicu to su gore navedene vrijednosti SENSOR_CO), proslijedite ga konstruktoru, jednom pozovite begin() u setup() i provjerite njegov rezultat, a zatim očitavajte pomoću getPPM().