Skip to main content

Očitavanje koncentracije CO-a

Što prikazuje ovaj primjer​

Primjer bridgeBoard pokreće pločicu na zadanoj adresi 0x30 s predloškom SENSOR_CO za ćeliju SGX-4CO, a zatim svakih 2,5 sekunde ispisuje koncentraciju ugljikova monoksida u ppm.

Na ovoj pločici biblioteka komunicira s mostom ATtiny404, a ne izravno sa sklopom za prilagodbu signala i ADC-om: bilo koja adresa od 0x30 do 0x37 odabire taj način rada. Most postavlja LMP91000 i ADS1115 na unutarnjoj sabirnici pločice, pa LMPEN ne morate nigdje spajati.

Kôd primjera​

Select Board
bridgeBoard.ino
/**
**************************************************
*
* @file bridgeBoard.ino
* @brief See how to init a sensor on the new ATtiny404 bridge board revision,
*
* To successfully run the sketch:
* - Set the desired address using the jumpers on the back of the board
* (address = 0x30 + jumper offset, giving a range of 0x30-0x37)
* - Run the sketch and open serial monitor at 115200 baud!
*
* Note: on this board revision, LMPEN is hardwired to GND, so there's
* no configPin argument to pass - the constructor's third argument
* is ignored whenever the address falls in the bridge range (0x30-0x37).
*
* @authors @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Any additional boards on the same bus just need a different jumper setting
// (0x30-0x37), same as twoSensors.ino does for legacy boards with 0x49/0x4A/0x4B.
ElectrochemicalGasSensor sensor(SENSOR_CO, 0x30);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections and jumper address!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Na ovoj se pločici adresa postavlja pomoću DIP sklopke ADDRESS s tri prekidača na gornjoj strani, u gornjem lijevom kutu, a ne pomoću jumpera na stražnjoj strani, a zadana adresa 0x30 ne zahtijeva nikakvu izmjenu. LMPEN je preko 10 kΩ povučen na GND, a nije spojen izravno na njega; u oba slučaja na njega ništa ne spajate.

Očekivani rezultat u serijskom monitoru pri 115200 baud, nakon što pločica odgovori:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!
Sensor reading: 0.29711 PPM
Sensor reading: 0.29430 PPM
Sensor reading: 0.32846 PPM
Sensor reading: 0.29958 PPM

Zatim svakih 2,5 sekunde slijedi redak: Sensor reading: , koncentracija u ppm s pet decimala i PPM. Rezultat manji od nule ispisuje se kao 0.00000. Ako pločica ne odgovori, skica ispisuje ERROR: Can't init the sensor! Check connections and jumper address! i zaustavlja se.

Korištene funkcije​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns none

Izrađuje objekt senzora. Primjer predaje SENSOR_CO i 0x30, adresu pločice kako se isporučuje; na adresi od 0x30 do 0x37 biblioteka komunicira s mostom ATtiny404 na pločici.

ReturnsKonstruktor.

Parametri

ParametarTipOpis
_tsensorTypePredložak ćelije. Za ćeliju SGX-4CO na ovoj pločici koristite SENSOR_CO (70 nA/ppm, raspon ADC-a 4,096 V, pojačanje pojačala 14 kΩ, unutarnja nula 20 %).
_adcAddruint8_tI2C adresa. Zadano DEFAULT_ADC_ADDR, 0x49. Od 0x30 do 0x37 biblioteka komunicira s mostom ATtiny404 na pločici.
_configPinintGPIO koji biblioteka postavlja u nisku razinu dok šalje konfiguraciju sklopa za prilagodbu signala, a inače u visoku. Ne koristi se na adresi od 0x30 do 0x37. Zadano -1, nijedan.
bool begin()returns bool

Pokreće I2C pomoću Wire.begin(), zatim na adresi mosta provjerava odgovara li most, šalje mu pojačanje ADC-a i brzinu podataka iz predloška te šalje konfiguraciju sklopa za prilagodbu signala. Svaki korak čeka odgovor mosta do 500 ms.

Returnstrue ako je svaki korak uspio, false ako pločica nije odgovorila ili je prijavila pogrešku.

double getPPM()returns double

Traži od mosta jednu ADC konverziju izlaza sklopa za prilagodbu signala, oduzima unutarnju nulu (20 % referentnih 2,5 V za SENSOR_CO), dodaje kalibraciju nule i pretvara struju ćelije u ppm pomoću osjetljivosti iz predloška.

ReturnsKoncentracija plina u ppm. Negativan rezultat vraća se kao 0.

double getPPB()returns double

Isto mjerenje kao getPPM(), u dijelovima na milijardu. Primjer ga prikazuje kao alternativu u komentaru.

ReturnsgetPPM() pomnožen s 1000.

Sve zajedno​

Izradite objekt s SENSOR_CO i adresom pločice, jednom pozovite begin() u setup() i provjerite njegov rezultat, a zatim pozovite getPPM() kad god želite očitanje. Za drugu pločicu na istoj sabirnici postavite drugu adresu pomoću njezinih sklopki za adresu i izradite drugi objekt s tom adresom.