Skip to main content

Očitavanje dvaju senzora na jednoj sabirnici

Što ovaj primjer prikazuje​

Primjer twoSensors očitava dvije pločice na jednoj I2C sabirnici. Stvara po jedan objekt senzora za svaku pločicu, svaki sa svojom predpostavkom i adresom: sensorCO na ADC adresi 0x4A s LMPEN na GPIO 25 te sensorNO2 na 0x49 s LMPEN na GPIO 32. Prvo očitanje ispisuje u ppm, a drugo u ppb svakih 2,5 sekundi. Na tim adresama biblioteka izravno komunicira s ADS1115 i LMP91000 svake pločice, a ne preko ATtiny404 mosta, a zaglavlje skice traži da LMPEN svake pločice bude spojen na GPIO. Pogledajte pregled biblioteke da vidite kako adresa to određuje.

Na ovoj pločici ADS1115 adresa postavlja se lemnim jumperima JP2 (0x49, zatvoren u isporuci), JP3 (0x4A) i JP4 (0x4B). Pločica za sensorNO2 ostavlja JP2 zatvoren za 0x49. Na pločici za sensorCO prerežite JP2, a zatim premostite JP3 za 0x4A. Na svakoj pločici mora biti zatvoren točno jedan od jumpera JP2, JP3 i JP4. Pogledajte Detalji o hardveru za tablicu jumpera i kombinacije koje treba izbjegavati.

Primjer prosljeđuje SENSOR_CO i SENSOR_NO2, predpostavke biblioteke za ćelije ugljikova monoksida i dušikova dioksida. Za pločicu s ovom ćelijom dušikova oksida SGX-4NO-250 na njezinoj liniji upotrijebite SENSOR_NO: 400 nA po ppm, pojačanje pojačala od 120 kΩ i pozitivan pomak (bias) od 12 %.

Kôd primjera​

Popis je datoteka iz biblioteke na pričvršćenom commitu. Izostavljeni su samo retci s komentarima: onaj koji spominje stari konektor i retci zaglavlja koji vode na stranice drugih proizvoda u trgovini.

Select Board
twoSensors.ino
/**
**************************************************
*
* @file twoSensors.ino
* @brief See how to init two sensors and make two readings of PPM of gas.
*
* To successfully run the sketch:
* - Set different addresses using the jumpers on the back of the breakout
* - Connect LMPEN pins to a GPIO pin so the breakouts can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Create two different sensor objects
ElectrochemicalGasSensor sensorCO(SENSOR_CO, 0x4A, 25);
ElectrochemicalGasSensor sensorNO2(SENSOR_NO2, 0x49, 32);
// To see how the custom addresses are determined, check customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init breakout #1
if (!sensorCO.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("CO sensor initialized successfully!");

// Init breakout #2
if (!sensorNO2.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("NO2 sensor initialized successfully!");
}

void loop()
{
// Make the reading of CO and print it
double COreading = sensorCO.getPPM();

// Print the reading with 5 digits of precision
Serial.print("CO sensor reading: ");
Serial.print(COreading, 5);
Serial.println(" PPM");

// Make the reading of NO2 and print it
double NO2reading = sensorNO2.getPPB();

// Print the reading with 5 digits of precision
Serial.print("NO2 sensor reading: ");
Serial.print(NO2reading, 5);
Serial.println(" PPB");

// Wait a bit before reading again
delay(2500);
}

Očekivani rezultat sa SENSOR_NO na obje linije (očitanja u čistom zraku; vaša će se razlikovati):

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
CO sensor initialized successfully!
NO2 sensor initialized successfully!
CO sensor reading: 0.00606 PPM
NO2 sensor reading: 5.89242 PPB
CO sensor reading: 0.00588 PPM
NO2 sensor reading: 5.92183 PPB
CO sensor reading: 0.00621 PPM
NO2 sensor reading: 6.27184 PPB

Očitanja dolaze u parovima redaka koji počinju s CO sensor reading: (u ppm, završava s PPM) i NO2 sensor reading: (u ppb, završava s PPB), jedan par svakih 2,5 sekundi, svaka vrijednost s pet decimala. Oznake dolaze iz skice, bez obzira na to koju predpostavku proslijedite. Ako bilo koji begin() ne uspije, skica ispisuje ERROR: Can't init the sensor! Check connections! i tu se zaustavlja.

Korištene funkcije​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Stvara po jedan objekt senzora za svaku pločicu: u primjeru sensorCO i sensorNO2. Ništa se ne šalje preko I2C dok ne pozovete begin().

ReturnsObjekt senzora.

Parametri

TipNazivOpis
sensorType_tPredpostavka ćelije, u primjeru SENSOR_CO i SENSOR_NO2. SENSOR_NO je ona za ćeliju ove pločice.
uint8_t_adcAddrI2C adresa pločice, u primjeru 0x4A i 0x49. Za adresu od 0x30 do 0x37 biblioteka komunicira s ATtiny404 mostom te pločice; za svaku drugu komunicira s ADS1115 na toj adresi i izravno s LMP91000.
int_configPinGPIO spojen na LMPEN te pločice, u primjeru 25 i 32. Biblioteka ga drži u niskom stanju samo dok konfigurira LMP91000 te pločice. Zanemaruje se na adresama od 0x30 do 0x37.
sensorCO.begin()returns bool

Pokreće I2C pomoću Wire.begin() i pokreće jednu pločicu. Za adresu od 0x30 do 0x37 provjerava odgovara li most pločice i preko njega šalje postavke ADC-a i ulaznog stupnja, čekajući do 500 ms za svaki korak. Za svaku drugu adresu pokreće ADS1115 na toj adresi s pojačanjem iz predpostavke i najsporijom brzinom podataka, zatim konfigurira LMP91000 (pojačanje, opterećenje, referencu, unutarnju nulu, bias i način rada), pritom držeći GPIO _configPin u niskom stanju. sensorNO2.begin() radi isto za drugu pločicu.

Returnstrue kada su svi koraci uspjeli, inače false.

sensorCO.getPPM()returns double

Uzima jedno ADC očitanje s te pločice i pretvara ga: oduzima unutarnju nulu (2,5 V puta postotak unutarnje nule iz predpostavke), dodaje kalibraciju nule, dijeli s pojačanjem pojačala da dobije struju ćelije te to dijeli s nA po ppm iz predpostavke.

ReturnsKoncentracija plina u ppm. Negativan rezultat vraća se kao 0.

sensorNO2.getPPB()returns double

Uzima jedno očitanje s druge pločice pomoću getPPM() i množi ga s 1000.

ReturnsKoncentracija plina u ppb.

Sastavljanje cjeline​

Svaka pločica dobiva vlastiti objekt senzora na vlastitoj adresi, a obje dijele jednu I2C sabirnicu. Skica pokreće prvu pločicu, zatim drugu, i zaustavlja se na prvoj koja ne uspije. U loop() očitava obje pločice i ispisuje oba očitanja zajedno.