Koristite vlastitu konfiguraciju senzora
Što prikazuje ovaj primjer
Primjer customConfig iz biblioteke gradi vlastiti sensorType umjesto
korištenja unaprijed definirane postavke, pomoću njega stvara senzor i ispisuje koncentraciju plina u
ppm svakih 2,5 sekunde.
Dugi komentar iznad SENSOR_CUSTOM navodi što koja vrijednost postavlja i
konstante koje možete odabrati; uredite ih prema tehničkom listu svog senzora. Za
usporedbu, postavka SENSOR_NO2 iz biblioteke za SGX-4NO2 ćeliju ove pločice
koristi sljedeće vrijednosti:
| Polje | SENSOR_CUSTOM u primjeru | Postavka SENSOR_NO2 |
|---|---|---|
nanoAmperesPerPPM | 100.0F | -600.0F |
internalZeroCalibration | 0 | 0 |
adsGain | ADS_GAIN_4_096V | ADS_GAIN_2_048V |
TIA_GAIN_IN_KOHMS | TIA_GAIN_120_KOHM | TIA_GAIN_35_KOHM |
RLOAD | RLOAD_10_OHM | RLOAD_10_OHM |
REF_SOURCE | REF_EXTERNAL | REF_EXTERNAL |
INTERNAL_ZERO | INTERNAL_ZERO_20_PERCENT | INTERNAL_ZERO_67_PERCENT |
BIAS_SIGN | BIAS_SIGN_NEGATIVE | BIAS_SIGN_NEGATIVE |
BIAS | BIAS_0_PERCENT | BIAS_0_PERCENT |
FET_SHORT | FET_SHORT_DISABLED | FET_SHORT_DISABLED |
OP_MODE | OP_MODE_3LEAD_AMP_CELL | OP_MODE_3LEAD_AMP_CELL |
Kod primjera
/**
**************************************************
*
* @file customConfig.ino
* @brief Create a custom config for the LMP91000 and upload it to the device.
* This enables you to use this breakout with any electrochemical sensor.
*
* To successfully run the sketch:
* - Edit the custom configuration
* - Connect LMPEN to any GPIO pin
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/
// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"
/**
* Here are parameters to configure for the custom sensor:
*
* nanoAmperesPerPPM: From the datasheet of the particular electrochemical
* sensor, used in the calculation of PPM/PPB
*
* internalZeroCalibration: A fixed value which is summed to the voltage
* measured by the ADS. The value here should make the reading be
* just barely 0 PPM when the sensor is in a place with none of the target gas
*
* adsGain: The gain of the ADS
* The voltage here represents the max range which it can measure
* ADS_GAIN_6_144V 6.144 V
* ADS_GAIN_4_096V 4.096 V
* ADS_GAIN_2_048V 2.048 V
* ADS_GAIN_1_024V 1.024 V
* ADS_GAIN_0_512V 0.512 V
* ADS_GAIN_0_256V 0.256 V
*
* TIA_GAIN_IN_KOHMS: The gain of the amplifier
* This increases the sensitivity of the measurement
* TIA_GAIN_EXTERNAL External resistance
* TIA_GAIN_2_75_KOHM 2.75 kOhm
* TIA_GAIN_3_5_KOHM 3.5 kOhm
* TIA_GAIN_7_KOHM 7 kOhm
* TIA_GAIN_14_KOHM 14 kOhm
* TIA_GAIN_35_KOHM 35 kOhm
* TIA_GAIN_120_KOHM 120 kOhm
* TIA_GAIN_350_KOHM 350 kOhm
*
* RLOAD: The load resistor in the LMP91000
* Specified in the electrochemical sensor's datasheet
* RLOAD_10_OHM 10 Ohm
* RLOAD_33_OHM 33 Ohm
* RLOAD_50_OHM 50 Ohm
* RLOAD_100_OHM 100 Ohm
*
* REF_SOURCE: Source of the control voltage reference
* For our breakout, use external, there's a 2.5V external
* reference voltage
* REF_INTERNAL Internal
* REF_EXTERNAL External
*
* INTERNAL_ZERO: Internal zero selection
* If the electrochemical sensor has a positive polarity, you
* would usually want to use 20% for the most headroom in the signal
* INTERNAL_ZERO_20_PERCENT 20%
* INTERNAL_ZERO_50_PERCENT 50%
* INTERNAL_ZERO_67_PERCENT 67%
* INTERNAL_ZERO_BYPASSED Internal zero bypassed
*
* BIAS_SIGN: The polarity of the bias voltage
* BIAS_SIGN_NEGATIVE Negative
* BIAS_SIGN_POSITIVE Positive
*
* BIAS: Added bias, percentage of the reference voltage
* Most sensors don't require this, check each sensor's datasheet
* BIAS_0_PERCENT 0%
* BIAS_1_PERCENT 1%
* BIAS_2_PERCENT 2%
* BIAS_4_PERCENT 4%
* BIAS_6_PERCENT 6%
* ...
* BIAS_22_PERCENT 22%
* BIAS_24_PERCENT 24%
*
* FET_SHORT: Short the FET
* Used to perserve the electrochemical sensor
* Has to be disabled for the sensor to be operable
* FET_SHORT_DISABLED Disabled
* FET_SHORT_ENABLED Enabled
*
* OP_MODE: Mode of operation
* OP_MODE_DEEP_SLEEP Deep Sleep (default)
* OP_MODE_2LEAD_GROUND_CELL 2-lead ground referred galvanic cell
* OP_MODE_STANDBY Standby
* OP_MODE_3LEAD_AMP_CELL 3-lead amperometric cell
* OP_MODE_TEMPERATURE_TIA_OFF Temperature measurement (TIA Off)
* OP_MODE_TEMPERATURE_TIA_ON Temperature measurement (TIA On)
*
* For more details, check thge LMP91000 datasheet, chapter 7.6
*/
// Here is an example of a custom configuration:
const sensorType SENSOR_CUSTOM = {
100.0F, // nanoAmperesPerPPM
0, // internalZeroCalibration
ADS_GAIN_4_096V, // adsGain
TIA_GAIN_120_KOHM, // TIA_GAIN_IN_KOHMS
RLOAD_10_OHM, // RLOAD
REF_EXTERNAL, // REF_SOURCE
INTERNAL_ZERO_20_PERCENT, // INTERNAL_ZERO
BIAS_SIGN_NEGATIVE, // BIAS_SIGN
BIAS_0_PERCENT, // BIAS
FET_SHORT_DISABLED, // FET_SHORT
OP_MODE_3LEAD_AMP_CELL, // OP_MODE
};
// Create the sensor object with the custom type
ElectrochemicalGasSensor sensor(SENSOR_CUSTOM);
void setup()
{
Serial.begin(115200); // For debugging
// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}
Serial.println("Sensor initialized successfully!");
}
void loop()
{
// Make the reading
double reading = sensor.getPPM();
// Print the reading with 5 digits of precision
Serial.println("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");
// Wait a bit before reading again
delay(2500);
}
Očekivani rezultat:
Sensor initialized successfully!
Zatim program svakih 2,5 sekunde u jednom retku ispisuje Sensor reading:, a u sljedećem koncentraciju u ppm s pet decimala, nakon koje slijedi PPM: ovaj primjer ispisuje oznaku pomoću println(). Ako begin() ne uspije, ispisuje ERROR: Can't init the sensor! Check connections! i zaustavlja se.
Korištene funkcije
ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensorStvara objekt senzora. Ništa se ne šalje pločici dok ne pozovete begin(). Adresa određuje kako begin() komunicira s pločicom: od 0x30 do 0x37 šalje naredbe čipu ATtiny404, a od 0x48 do 0x4B (DEFAULT_ADC_ADDR je 0x49) izravno se obraća čipu ADS1115 i čipu LMP91000 na toj adresi.
ReturnsObjekt senzora.
Parametri
| Tip | Naziv | Opis |
|---|---|---|
sensorType | _t | Postavke ćelije: unaprijed definirana postavka ili vaš vlastiti sensorType. Primjer prosljeđuje SENSOR_CUSTOM. |
uint8_t | _adcAddr | Adresa s kojom begin() komunicira, prema zadanim postavkama 0x49; primjer je ostavlja na zadanoj vrijednosti. |
int | _configPin | GPIO za pin za omogućavanje LMP91000 (LMPEN), koristi se samo kod adresa od 0x48 do 0x4B. Prema zadanim postavkama -1 (nema pina); primjer ga ne prosljeđuje. |
sensorType sadrži ovim redoslijedom: nanoAmperesPerPPM i
internalZeroCalibration (oba double), zatim adsGain, TIA_GAIN_IN_KOHMS,
RLOAD, REF_SOURCE, INTERNAL_ZERO, BIAS_SIGN, BIAS, FET_SHORT i
OP_MODE (svaki uint8_t, postavlja se konstantama koje navodi komentar u primjeru).
sensor.begin()returns boolPokreće Wire i zapisuje konfiguraciju na pločicu. Od 0x30 do 0x37 provjerava odgovara li ATtiny404, zatim mu šalje pojačanje i brzinu podataka ADC-a te konfiguraciju LMP91000, pri čemu svaki korak čeka odgovor do 500 ms. Od 0x48 do 0x4B pokreće ADS1115 na toj adresi, postavlja pojačanje iz konfiguracije i najsporiju brzinu podataka te zapisuje konfiguraciju LMP91000, pri čemu povlači _configPin na nisku razinu dok to traje, ako je zadan. Pozovite ga jednom u setup().
Returnstrue ako su svi koraci uspjeli, inače false.
sensor.getPPM()returns doubleUzima novo očitanje ADC-a i pretvara ga u koncentraciju plina pomoću vaše konfiguracije: napon umanjen za unutarnju nulu, uvećan za internalZeroCalibration, podijeljen s TIA pojačanjem i s nanoAmperesPerPPM. Negativan rezultat vraća se kao 0.
ReturnsKoncentracija plina u ppm.
Sve zajedno
Program definira SENSOR_CUSTOM i stvara senzor s njim prije nego se pokrene
setup(). begin() zapisuje ADC raspon konfiguracije i postavke ulaznog
stupnja; ako ne uspije, program ispisuje pogrešku i ostaje u beskonačnoj
petlji. U loop() svaki poziv getPPM() ponovno očitava ćeliju, a program
ispisuje vrijednost i čeka 2,5 sekunde.