Skip to main content

Očitavanje dvaju senzora na jednoj sabirnici

Što ovaj primjer prikazuje​

Primjer twoSensors iz biblioteke očitava dvije pločice na jednoj I2C sabirnici. Stvara po jedan objekt senzora za svaku pločicu, pokreće oba i svake 2,5 sekunde ispisuje očitanje ugljikova monoksida u ppm i očitanje NO2 u ppb.

Primjer stvara sensorCO s predloškom SENSOR_CO na adresi 0x4A s LMPEN na GPIO 25, te sensorNO2 s predloškom SENSOR_NO2, predloškom biblioteke za ćeliju SGX-4NO2 ove pločice, na adresi 0x49 s LMPEN na GPIO 32.

Kôd primjera​

Select Board
twoSensors.ino
/**
**************************************************
*
* @file twoSensors.ino
* @brief See how to init two sensors and make two readings of PPM of gas.
*
* To successfully run the sketch:
* - Set different addresses using the jumpers on the back of the breakout
* - Connect LMPEN pins to a GPIO pin so the breakouts can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Create two different sensor objects
ElectrochemicalGasSensor sensorCO(SENSOR_CO, 0x4A, 25);
ElectrochemicalGasSensor sensorNO2(SENSOR_NO2, 0x49, 32);
// To see how the custom addresses are determined, check customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init breakout #1
if (!sensorCO.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("CO sensor initialized successfully!");

// Init breakout #2
if (!sensorNO2.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("NO2 sensor initialized successfully!");
}

void loop()
{
// Make the reading of CO and print it
double COreading = sensorCO.getPPM();

// Print the reading with 5 digits of precision
Serial.print("CO sensor reading: ");
Serial.print(COreading, 5);
Serial.println(" PPM");

// Make the reading of NO2 and print it
double NO2reading = sensorNO2.getPPB();

// Print the reading with 5 digits of precision
Serial.print("NO2 sensor reading: ");
Serial.print(NO2reading, 5);
Serial.println(" PPB");

// Wait a bit before reading again
delay(2500);
}

Očekivani rezultat:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
CO sensor initialized successfully!
NO2 sensor initialized successfully!

Zatim skica svake 2,5 sekunde ispisuje dva retka: jedan koji počinje s CO sensor reading:, a iza njega koncentraciju u ppm, i jedan koji počinje s NO2 sensor reading:, a iza njega koncentraciju NO2 u ppb, svaku s pet decimala. Ako se bilo koji senzor ne uspije pokrenuti, skica ispisuje ERROR: Can't init the sensor! Check connections! i zaustavlja se.

Korištene funkcije​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Stvara jedan objekt senzora. Ništa se ne šalje pločici dok ne pozovete begin(). Adresa određuje kako begin() komunicira s pločicom: od 0x30 do 0x37 šalje naredbe čipu ATtiny404, a od 0x48 do 0x4B (DEFAULT_ADC_ADDR je 0x49) izravno se obraća čipovima ADS1115 i LMP91000 na toj adresi. Primjer stvara dva objekta, po jedan za svaku pločicu.

ReturnsObjekt senzora.

Parametri

TipNazivOpis
sensorType_tPredložak ćelije. Primjer prosljeđuje SENSOR_CO i SENSOR_NO2, predložak za ćeliju SGX-4NO2 ove pločice.
uint8_t_adcAddrAdresa s kojom begin() komunicira, prema zadanim postavkama 0x49; primjer prosljeđuje 0x4A i 0x49.
int_configPinGPIO za pin za omogućivanje LMP91000 (LMPEN), koristi se samo na 0x48 do 0x4B. Prema zadanim postavkama -1 (nema); primjer prosljeđuje 25 i 32.
sensor.begin()returns bool

Pokreće Wire i upisuje predložak na jednu pločicu. Od 0x30 do 0x37 provjerava odgovara li ATtiny404, zatim mu šalje pojačanje ADC-a, brzinu podataka i konfiguraciju LMP91000, pri čemu svaki korak čeka odgovor do 500 ms. Od 0x48 do 0x4B pokreće ADS1115 na toj adresi, postavlja pojačanje iz predloška i najsporiju brzinu podataka te upisuje konfiguraciju LMP91000, pritom povlači _configPin na nisku razinu ako je zadan. Pozovite ga jednom za svaki senzor u setup().

Returnstrue ako su svi koraci uspjeli, inače false.

sensor.getPPM()returns double

Uzima novo očitanje ADC-a s jednog senzora i pretvara ga u koncentraciju plina: napon minus unutarnja nula, plus kalibracijski pomak, podijeljeno s TIA pojačanjem i osjetljivošću ćelije iz predloška. Negativan rezultat vraća se kao 0.

ReturnsKoncentracija plina u ppm.

sensor.getPPB()returns double

Isto očitanje kao getPPM(), pomnoženo s 1000. Primjer njime očitava NO2 senzor.

ReturnsKoncentracija plina u ppb.

Sve zajedno​

Oba objekta senzora stvaraju se prije izvođenja setup() i razlikuju se u predlošku, adresi i pinu LMPEN. setup() pokreće sensorCO, zatim sensorNO2, te se zaustavlja u beskonačnoj petlji kod prvog koji se ne uspije pokrenuti. Svaki prolaz loop() očitava sensorCO pomoću getPPM() i sensorNO2 pomoću getPPB(), ispisuje obje vrijednosti s pet decimala i čeka 2,5 sekunde.