Skip to main content

Usrednjeno očitanje

Što ovaj primjer prikazuje​

Primjer averagedMeasurement usrednjava nekoliko očitanja prije nego što ispiše jedno. Uzima NUM_READINGS (5) očitanja s SECS_BETWEEN_READINGS (3) sekunde razmaka među njima, ispisuje prosjek u PPM, zatim čeka 2,5 sekunde i počinje ispočetka. Senzor stvara s konfiguracijom SENSOR_CO i bez adrese, pa konstruktor koristi zadanu, DEFAULT_ADC_ADDR (0x49).

Na ovoj pločici ne trebate spajati LMPEN, bez obzira na to što piše u komentarima skice: pločica ga sama drži na niskoj razini.

Kôd primjera​

Select Board
averagedMeasurement.ino
/**
**************************************************
*
* @file averagedMeasurement.ino
* @brief See how to use a built-in function to make an averaged measurement
*
* To successfully run the sketch:
* - Connect LMPEN pin to GND or a GPIO pin so the breakout can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// How many readings to average from and how long to wait between them
#define NUM_READINGS 5
#define SECS_BETWEEN_READINGS 3

// Configurations for each of the sensor types are in sensorConfigData.h in the library's 'src' folder
// Create the sensor object with the according type
ElectrochemicalGasSensor sensor(SENSOR_CO);

// If you are using a custom I2C address (for multiple sensors) use:
// ElectrochemicalGasSensor sensor(SENSOR_CO, 0x4A, 25);
// For more details on this, see customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the averaged reading
// This is a blocking function, so it will take a while before code continues
double reading = sensor.getAveragedPPM(NUM_READINGS, SECS_BETWEEN_READINGS);

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getAveragedPPB(NUM_READINGS, SECS_BETWEEN_READINGS);

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Što ova pločica ispisuje s neizmijenjenom skicom, još nije izmjereno. Kad je ova pločica testirana preko Qwiic konektora, I2C pretraga pronašla je samo jednu adresu, 0x30, a s MicroPython bibliotekom begin() nije uspio za senzor stvoren na 0x49, zadanoj adresi koju koristi ova skica. Ako begin() ne uspije, skica ispisuje ERROR: Can't init the sensor! Check connections! i zaustavlja se.

Kad begin() uspije, skica ispisuje:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Nakon toga redak Sensor reading: iza kojeg slijedi vrijednost s pet decimala i PPM stiže jednom u svakom krugu od pet očitanja.

Korištene funkcije​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Stvara objekt senzora saždanom konfiguracijom senzora, adresom i pinom LMPEN. Ništa se ne šalje dok ne pozovete begin(). begin() na temelju adrese odabire kako će komunicirati s pločicom: od 0x30 do 0x37 koristi naredbe ATtiny404 mosta i zanemaruje treći argument; svaka druga adresa uzima se kao vlastita adresa ADS1115, a LMP91000 se upisuje izravno.

ReturnsObjekt senzora.

Parametri

TipNazivOpis
sensorType_tPostavke ulaznog stupnja i pretvorbe, u primjeru SENSOR_CO. Predlošci se nalaze u datoteci src/sensorConfigData.h biblioteke.
uint8_t_adcAddrAdresa, DEFAULT_ADC_ADDR (0x49) kad je izostavljena, kao u primjeru.
int_configPinGPIO pin spojen na LMPEN, -1 (nijedan) kad je izostavljen. Ne koristi se za adresu od 0x30 do 0x37.
sensor.begin()returns bool

Pokreće I2C pomoću Wire.begin(). Za adresu od 0x30 do 0x37 provjerava odgovara li most, šalje mu pojačanje ADC-a i najsporiju brzinu podataka ADC-a, zatim postavke LMP91000; svaka naredba mostu čeka do 500 ms. Za svaku drugu adresu pokreće ADS1115 na toj adresi s istim pojačanjem i brzinom podataka, postavlja pin LMPEN u visoko stanje ako je zadan, zatim upisuje postavke LMP91000 dok taj pin drži u niskom stanju.

Returnstrue ako su svi koraci uspjeli, inače false.

sensor.getAveragedPPM(uint8_t _numMeasurements = 5, uint8_t _secondsDelay = 2)returns double

Uzima _numMeasurements očitanja funkcijom getPPM(), nakon svakog čeka _secondsDelay sekundi i vraća njihovu srednju vrijednost. Blokira dok se ne uzmu sva očitanja. getPPM() za negativan rezultat vraća 0, pa se takvo očitanje računa kao 0.

ReturnsUsrednjena koncentracija u PPM.

Parametri

TipNazivOpis
uint8_t_numMeasurementsKoliko očitanja treba usrednjiti, u primjeru NUM_READINGS (5).
uint8_t_secondsDelaySekunde čekanja nakon svakog očitanja, u primjeru SECS_BETWEEN_READINGS (3).
sensor.getAveragedPPB(uint8_t _numMeasurements = 5, uint8_t _secondsDelay = 2)returns double

Alternativa u primjeru koja je pretvorena u komentar: rezultat getAveragedPPM() pomnožen s 1000.

ReturnsUsrednjena koncentracija u PPB.

Parametri

TipNazivOpis
uint8_t_numMeasurementsKoliko očitanja treba usrednjiti.
uint8_t_secondsDelaySekunde čekanja nakon svakog očitanja.

Sve zajedno​

SENSOR_CO je predložak za SGX-4CO ćeliju za ugljikov monoksid. Biblioteka još nema predložak za SGX-4OX-ROHS ćeliju za kisik ove pločice, pa se vrijednost koju primjer ispisuje izračunava s postavkama CO ćelije. Stranica prilagođena konfiguracija pokazuje kako napisati vlastitu.