Skip to main content

Očitavanje senzora

Što ovaj primjer prikazuje​

Primjer bridgeBoard pokreće pločicu preko njezina ATtiny404 na adresi 0x30, šalje analognom ulaznom stupnju njegove postavke i ispisuje očitanje svakih 2,5 sekunde. Vaš kontroler komunicira isključivo s ATtiny404; on prosljeđuje postavke čipu LMP91000 i umjesto vas očitava ADS1115.

Povežite pločicu Qwiic kabelom ili spojite 3V3, GND, SDA1 i SCL1 s gornjeg headera. LMPEN ne morate spajati: pločica ga sama drži na niskoj razini. Gdje komentari u skici spominju adresne jumpere na stražnjoj strani pločice, ova pločica umjesto njih koristi ADDRESS preklopnik s tri položaja na gornjoj strani.

Kod primjera​

Select Board
bridgeBoard.ino
/**
**************************************************
*
* @file bridgeBoard.ino
* @brief See how to init a sensor on the new ATtiny404 bridge board revision,
*
* To successfully run the sketch:
* - Set the desired address using the jumpers on the back of the board
* (address = 0x30 + jumper offset, giving a range of 0x30-0x37)
* - Run the sketch and open serial monitor at 115200 baud!
*
* Note: on this board revision, LMPEN is hardwired to GND, so there's
* no configPin argument to pass - the constructor's third argument
* is ignored whenever the address falls in the bridge range (0x30-0x37).
*
*
* @authors @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Any additional boards on the same bus just need a different jumper setting
// (0x30-0x37), same as twoSensors.ino does for legacy boards with 0x49/0x4A/0x4B.
ElectrochemicalGasSensor sensor(SENSOR_CO, 0x30);

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections and jumper address!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Očekivani rezultat:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Nakon toga svakih 2,5 sekunde stiže redak Sensor reading: iza kojeg slijedi vrijednost s pet decimala i PPM. Ako pločica ne odgovori, skica ispisuje ERROR: Can't init the sensor! Check connections and jumper address! i zaustavlja se.

Korištene funkcije​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Stvara objekt senzora s konfiguracijom senzora i adresom. Ništa se ne šalje pločici dok ne pozovete begin(). Adresa od 0x30 do 0x37 govori biblioteci da je riječ o pločici s ATtiny404 mostom, a treći se argument tada zanemaruje.

ReturnsObjekt senzora.

Parametri

TipNazivOpis
sensorType_tPostavke ulaznog stupnja i pretvorbe, npr. SENSOR_CO. Predlošci se nalaze u datoteci src/sensorConfigData.h u biblioteci.
uint8_t_adcAddrAdresa pločice. Za ovu pločicu koristite 0x30 do 0x37, u skladu s ADDRESS preklopnikom. Za bilo koju drugu adresu, npr. zadanu DEFAULT_ADC_ADDR (0x49), begin() izravno komunicira s ADS1115 na toj adresi, a ne s mostom.
int_configPinGPIO za LMPEN na izravno spojenoj pločici. Na ovoj pločici se ne koristi.
sensor.begin()returns bool

Pokreće I2C pomoću Wire.begin(), provjerava odgovara li most, šalje mu pojačanje ADC-a i najsporiju brzinu podataka ADC-a, zatim šalje postavke za LMP91000 iz konfiguracije senzora. Svaka naredba mostu čeka odgovor do 500 ms.

Returnstrue kada su svi koraci uspjeli, false kada most nije odgovorio ili je prijavio pogrešku.

sensor.getPPM()returns double

Traži od mosta jednu ADC pretvorbu i pretvara napon u koncentraciju: oduzima internu nulu (dio referentnog napona pločice od 2,5 V), dodaje kalibraciju nule iz konfiguracije, dijeli s TIA pojačanjem da dobije struju ćelije, zatim dijeli s nanoamperima po PPM-u iz konfiguracije. Negativan rezultat vraća se kao 0.

ReturnsKoncentracija u PPM-u, izračunata sa konfiguracijom senzora koju ste proslijedili konstruktoru.

sensor.getPPB()returns double

Alternativa iz primjera koja je pretvorena u komentar: isto očitanje kao getPPM(), pomnoženo s 1000.

ReturnsKoncentracija u PPB-u.

Sve zajedno​

SENSOR_CO je predložak za SGX-4CO ćeliju za ugljikov monoksid. Biblioteke još nemaju predložak za SGX-4OX-ROHS ćeliju za kisik na ovoj pločici, pa se vrijednost koju primjer ispisuje izračunava s postavkama CO ćelije. Pppristranost (bias) i pojačanje ulaznog stupnja postavljate sami:

  • Kopirajte jedan od predložaka iz src/sensorConfigData.h u svoju skicu kao vlastiti sensorType i proslijedite ga konstruktoru s adresom 0x30.
  • Ćeliji je potreban bias od −600 mV. S referencom pločice od 2,5 V to je BIAS_SIGN_NEGATIVE uz BIAS_24_PERCENT (24 % od 2,5 V iznosi 0,6 V).
  • Zadržite REF_EXTERNAL: pločica ima vanjsku referencu od 2,5 V.
  • Izlaz ćelije na zraku iznosi 0,1 ± 0,03 mA, a izlaz je logaritamski, S = K ln(1/(1-C)), pa ga linearni izračun PPM-a u biblioteci ne pretvara izravno u % vol.

Nakon uključivanja napajanja ćeliji može trebati do 15 minuta da se stabilizira, stoga je pustite da radi prije nego što povjerujete očitanju.

Do osam pločica dijeli jednu sabirnicu: svakoj dodijelite vlastitu adresu ADDRESS preklopnikom i izradite po jedan ElectrochemicalGasSensor za svaku adresu, od 0x30 do 0x37.