Skip to main content

Jedan senzor

Što prikazuje ovaj primjer​

Primjer singleSensor stvara jedan objekt senzora s konfiguracijom SENSOR_CO, pokreće ga i svake 2,5 sekunde ispisuje očitanje u PPM. Ne prosljeđuje adresu, pa konstruktor koristi zadanu, DEFAULT_ADC_ADDR (0x49).

Na ovoj pločici ne morate spajati LMPEN, bez obzira na to što piše u komentarima skice: pločica ga sama drži na niskoj razini.

Kod primjera​

Select Board
singleSensor.ino
/**
**************************************************
*
* @file singleSensor.ino
* @brief See how to init one sensor and make a simple reading of PPM of gas.
*
* To successfully run the sketch:
* - Connect LMPEN pin to GND or a GPIO pin so the breakout can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/

// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"

// Configurations for each of the sensor types are in sensorConfigData.h in the library's 'src' folder
// Create the sensor object with the according type
ElectrochemicalGasSensor sensor(SENSOR_CO);

// If you are using a custom I2C address (for multiple sensors) use:
// ElectrochemicalGasSensor sensor(SENSOR_SO2, 0x4B, 5);
// For more details on this, see customAddress.ino

void setup()
{
Serial.begin(115200); // For debugging

// Init the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}

Serial.println("Sensor initialized successfully!");
}

void loop()
{
// Make the reading
double reading = sensor.getPPM();

// If PPB is more relevant for your sensor, you can use:
// double reading = sensor.getPPB();

// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");

// Wait a bit before reading again
delay(2500);
}

Što ova pločica ispisuje s nepromijenjenom skicom još nije izmjereno. Kada je ova pločica testirana preko Qwiic konektora, I2C skeniranje pronašlo je samo jednu adresu, 0x30, a s MicroPython bibliotekom begin() nije uspio za senzor stvoren na adresi 0x49, zadanoj adresi koju koristi ova skica. Ako begin() ne uspije, skica ispisuje ERROR: Can't init the sensor! Check connections! i zaustavlja se.

Kada begin() uspije, skica ispisuje:

Serial MonitorAutoscrollShow timestampNewline115200 baud
Message (Enter to send message to the board)
Sensor initialized successfully!

Nakon toga svake 2,5 sekunde stiže redak Sensor reading: , iza kojeg slijedi vrijednost s pet decimala i PPM.

Korištene funkcije​

ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns ElectrochemicalGasSensor

Stvara objekt senzora s konfiguracijom senzora, adresom i LMPEN pinom. Ništa se ne šalje dok ne pozovete begin(). begin() prema adresi odabire način komunikacije s pločicom: od 0x30 do 0x37 koristi naredbe ATtiny404 mosta i zanemaruje treći argument; svaka druga adresa uzima se kao vlastita adresa ADS1115, a LMP91000 se upisuje izravno.

ReturnsObjekt senzora.

Parametri

TipNazivOpis
sensorType_tPostavke ulaznog stupnja i konverzije, u primjeru SENSOR_CO. Predlošci se nalaze u datoteci biblioteke src/sensorConfigData.h.
uint8_t_adcAddrAdresa, DEFAULT_ADC_ADDR (0x49) ako je izostavljena, kao u primjeru.
int_configPinGPIO pin spojen na LMPEN, -1 (nijedan) ako je izostavljen. Ne koristi se za adresu od 0x30 do 0x37.
sensor.begin()returns bool

Pokreće I2C pomoću Wire.begin(). Za adresu od 0x30 do 0x37 provjerava odgovara li most, šalje mu pojačanje ADC-a i najsporiju brzinu podataka ADC-a, zatim postavke LMP91000; svaka naredba mostu čeka do 500 ms. Za svaku drugu adresu pokreće ADS1115 na toj adresi s istim pojačanjem i brzinom podataka, postavlja LMPEN pin u visoku razinu ako je zadan, zatim upisuje postavke LMP91000, pritom taj pin drži u niskoj razini.

Returnstrue kada su svi koraci uspjeli, inače false.

sensor.getPPM()returns double

Izvodi jedno očitanje ADC-a i pretvara napon u koncentraciju: oduzima unutarnju nulu (dio referentnog napona od 2,5 V), dodaje nultu kalibraciju konfiguracije, dijeli s TIA pojačanjem kako bi dobio struju ćelije, zatim dijeli s nanoamperima po PPM konfiguracije. Negativan rezultat vraća se kao 0.

ReturnsKoncentracija u PPM, izračunata sa konfiguracijom senzora koju ste proslijedili konstruktoru.

sensor.getPPB()returns double

Alternativa u primjeru koja je zakomentirana: isto očitanje kao getPPM(), pomnoženo s 1000.

ReturnsKoncentracija u PPB.

Sve na okupu​

SENSOR_CO je predložak za SGX-4CO ćeliju ugljikova monoksida. Biblioteka još nema predložak za SGX-4OX-ROHS ćeliju kisika s ove pločice, pa se vrijednost koju primjer ispisuje izračunava s postavkama CO ćelije. Stranica prilagođena konfiguracija pokazuje kako napisati vlastitu.