Kalibracija nulte točke
Što prikazuje ovaj primjer
Primjer calibrateSensor iz biblioteke dodaje fiksni naponski pomak svakom očitanju ADC-a prije nego što se ono pretvori u ppm. Na zraku bez ciljanog plina podešavajte taj pomak sve dok očitanje nije tek nešto iznad 0.
Primjer stvara senzor s presetom za NH3 ćeliju, SENSOR_NH3, na adresi 0x49, s GPIO 32 kao pinom za omogućavanje (enable). SENSOR_SO2 je preset biblioteke za SGX-4SO2 ćeliju na ovoj pločici: zamijenite SENSOR_NH3 s SENSOR_SO2 u retku koji stvara sensor kako biste dobili vrijednosti za SO2.
Na ovoj pločici LMP91000 i ADS1115 nalaze se na vlastitoj sabirnici 2 pločice, a vaš kontroler im pristupa preko adrese pločice na Qwiic sabirnici: 0x30 kakva je isporučena, odnosno od 0x30 do 0x37 pomoću prekidača ADDRESS. Adresa 0x49 iz primjera obraća se izravno ADS1115. Umjesto toga adresu pločice proslijedite kao drugi argument konstruktora, na primjer ElectrochemicalGasSensor sensor(SENSOR_SO2, 0x30);. Gdje header kaže da LMPEN treba spojiti na GND ili na GPIO pin, na ovoj je pločici LMPEN već povučen na GND otpornikom od 10 kΩ i vodi također do mikrokontrolera na pločici, a na adresama pločice biblioteka zanemaruje argument enable pina, ovdje GPIO 32 (pogledajte Detalji o hardveru).
Ispis je datoteka biblioteke na fiksiranom commitu, osim nekoliko redaka koji sadrže samo komentare u njezinu headeru, a koji konektor nazivaju starijim imenom ili vode na druge Soldered proizvode; ti su retci izostavljeni.
Kôd primjera
/**
**************************************************
*
* @file calibrateSensor.ino
* @brief See how to calibrate an electrochemical sensor
*
* To successfully run the sketch:
* - Uncomment the #define in the library header file
* - Connect LMPEN pin to GND or a GPIO pin so the breakout can be configured
* - Run the sketch and open serial monitor at 115200 baud!
*
*
* @authors Robert @ soldered.com
***************************************************/
// Include the required library
#include "Electrochemical-Gas-Sensor-SOLDERED.h"
// This is the custom value we set for the calibration voltage
// This value is added to the voltage read from the ADC
// In an environment with 0 of the target gas, the voltage after calibration should be
// roughly 0, adjust customCalibration to get it to that value.
const double customCalibration = 0.05;
// Create the sensor object with the according type
ElectrochemicalGasSensor sensor(SENSOR_NH3, 0x49, 32);
void setup()
{
Serial.begin(115200); // For debugging
// Initialize the breakout
if (!sensor.begin())
{
// Can't init? Notify the user and go to infinite loop
Serial.println("ERROR: Can't init the sensor! Check connections!");
while (true)
delay(100);
}
//Set the custom calibration value
sensor.setCustomZeroCalibration(customCalibration);
Serial.println("Sensor initialized successfully!");
}
void loop()
{
// Make the reading
double reading = sensor.getPPM();
// This function will also print debug messages if the #define in
// the header file of the library is uncommented
// It will print:
// - The raw voltage measurement
// - Voltage without reference value
// - Voltage after calibration
// These values can help you adjust the internal zero calibration
// Print the reading with 5 digits of precision
Serial.print("Sensor reading: ");
Serial.print(reading, 5);
Serial.println(" PPM");
// Wait a bit before reading again
delay(2500);
}
Očekivani rezultat:
Sensor initialized successfully!
Zatim se svake 2,5 sekunde ispisuje redak Sensor reading: u ppm. Da biste vidjeli napone iza svakog očitanja, uklonite // ispred #define ELECTROCHEMICAL_SENSOR_DEBUG u datoteci biblioteke Electrochemical-Gas-Sensor-SOLDERED.h. Tada svako očitanje ispisuje i neobrađeni napon, napon bez referentne vrijednosti i napon nakon kalibracije.
Korištene funkcije
ElectrochemicalGasSensor(sensorType _t, uint8_t _adcAddr = DEFAULT_ADC_ADDR, int _configPin = -1)returns noneStvara objekt senzora iz preseta ćelije, adrese i neobveznog enable pina. Primjer koristi adresu 0x49 i GPIO 32.
ReturnsKonstruktor.
Parametri
| Parametar | Tip | Opis |
|---|---|---|
_t | sensorType | Preset ćelije. SENSOR_SO2 je preset za ćeliju ove pločice. |
_adcAddr | uint8_t | Adresa s kojom biblioteka komunicira. Od 0x30 do 0x37 je raspon mosta (bridge), određen prekidačem ADDRESS na pločici; bilo koja druga vrijednost komunicira izravno s ADS1115 na toj adresi. Zadano 0x49. |
_configPin | int | GPIO za liniju za omogućavanje (enable) analognog sučelja. Zanemaruje se na adresama od 0x30 do 0x37. Zadano -1. |
bool begin()returns boolPokreće I2C, provjerava odgovara li pločica te šalje pločici postavke ADC-a i LMP91000 iz preseta.
Returnstrue kada je pločica odgovorila i prihvatila sve postavke, inače false.
void setCustomZeroCalibration(double calibration)returns voidPostavlja naponski pomak koji se dodaje svakom očitanju prije pretvorbe u ppm. Zamjenjuje vlastitu vrijednost nulte kalibracije preseta, koja za SENSOR_SO2 iznosi 0.
ReturnsNišta.
Parametri
| Parametar | Tip | Opis |
|---|---|---|
calibration | double | Pomak u voltima. |
double getPPM()returns doublePločica izvodi jedno očitanje ADC-a i pretvara ga u koncentraciju plina, uključujući pomak nulte kalibracije. Rezultat manji od nule vraća se kao 0.
ReturnsKoncentracija plina u ppm.
Sve zajedno
Primjer počinje s 0,05. Postavite pločicu na zrak bez SO2, pratite napone za otklanjanje pogrešaka (debug) i podesite customCalibration tako da napon nakon kalibracije bude otprilike 0. Istu vrijednost upotrijebite s setCustomZeroCalibration() u vlastitoj skici.